acinclude.m4

   1 # This file is part of Autoconf.                       -*- Autoconf -*-\r
   2 \r
   3 # Copyright (C) 2004 Oren Ben-Kiki\r
   4 # This file is distributed under the same terms as the Autoconf macro files.\r
   5 \r
   6 ########## CHANGELOG ##################\r
   7 # 2009-01-14 Martin Mann\r
   8 # * DX_ARG_ABLE : new variable 'DX_FLAG_DX_CURRENT_FEATURE'\r
   9 # * DX_CLEAR_DEPEND : use of explicit variable 'DX_FLAG_DX_CURRENT_FEATURE'\r
  10 #   in AC_SUBST instead of 'DX_FLAG[]DX_CURRENT_FEATURE' which is rejected by\r
  11 #   newer autotools  \r
  12 \r
  13 # Generate automatic documentation using Doxygen. Works in concert with the\r
  14 # aminclude.m4 file and a compatible doxygen configuration file. Defines the\r
  15 # following public macros:\r
  16 #\r
  17 # DX_???_FEATURE(ON|OFF) - control the default setting fo a Doxygen feature.\r
  18 # Supported features are 'DOXYGEN' itself, 'DOT' for generating graphics,\r
  19 # 'HTML' for plain HTML, 'CHM' for compressed HTML help (for MS users), 'CHI'\r
  20 # for generating a separate .chi file by the .chm file, and 'MAN', 'RTF',\r
  21 # 'XML', 'PDF' and 'PS' for the appropriate output formats. The environment\r
  22 # variable DOXYGEN_PAPER_SIZE may be specified to override the default 'a4wide'\r
  23 # paper size.\r
  24 #\r
  25 # By default, HTML, PDF and PS documentation is generated as this seems to be\r
  26 # the most popular and portable combination. MAN pages created by Doxygen are\r
  27 # usually problematic, though by picking an appropriate subset and doing some\r
  28 # massaging they might be better than nothing. CHM and RTF are specific for MS\r
  29 # (note that you can't generate both HTML and CHM at the same time). The XML is\r
  30 # rather useless unless you apply specialized post-processing to it.\r
  31 #\r
  32 # The macro mainly controls the default state of the feature. The use can\r
  33 # override the default by specifying --enable or --disable. The macros ensure\r
  34 # that contradictory flags are not given (e.g., --enable-doxygen-html and\r
  35 # --enable-doxygen-chm, --enable-doxygen-anything with --disable-doxygen, etc.)\r
  36 # Finally, each feature will be automatically disabled (with a warning) if the\r
  37 # required programs are missing.\r
  38 #\r
  39 # Once all the feature defaults have been specified, call DX_INIT_DOXYGEN with\r
  40 # the following parameters: a one-word name for the project for use as a\r
  41 # filename base etc., an optional configuration file name (the default is\r
  42 # 'Doxyfile', the same as Doxygen's default), and an optional output directory\r
  43 # name (the default is 'doxygen-doc').\r
  44 \r
  45 ## ----------##\r
  46 ## Defaults. ##\r
  47 ## ----------##\r
  48 \r
  49 DX_ENV=""\r
  50 AC_DEFUN([DX_FEATURE_doc],  ON)\r
  51 AC_DEFUN([DX_FEATURE_dot],  ON)\r
  52 AC_DEFUN([DX_FEATURE_man],  OFF)\r
  53 AC_DEFUN([DX_FEATURE_html], ON)\r
  54 AC_DEFUN([DX_FEATURE_chm],  OFF)\r
  55 AC_DEFUN([DX_FEATURE_chi],  OFF)\r
  56 AC_DEFUN([DX_FEATURE_rtf],  OFF)\r
  57 AC_DEFUN([DX_FEATURE_xml],  OFF)\r
  58 AC_DEFUN([DX_FEATURE_pdf],  ON)\r
  59 AC_DEFUN([DX_FEATURE_ps],   ON)\r
  60 \r
  61 ## --------------- ##\r
  62 ## Private macros. ##\r
  63 ## --------------- ##\r
  64 \r
  65 # DX_ENV_APPEND(VARIABLE, VALUE)\r
  66 # ------------------------------\r
  67 # Append VARIABLE="VALUE" to DX_ENV for invoking doxygen.\r
  68 AC_DEFUN([DX_ENV_APPEND], [AC_SUBST([DX_ENV], ["$DX_ENV $1='$2'"])])\r
  69 \r
  70 # DX_DIRNAME_EXPR\r
  71 # ---------------\r
  72 # Expand into a shell expression prints the directory part of a path.\r
  73 AC_DEFUN([DX_DIRNAME_EXPR],\r
  74          [[expr ".$1" : '\(\.\)[^/]*$' \| "x$1" : 'x\(.*\)/[^/]*$']])\r
  75 \r
  76 # DX_IF_FEATURE(FEATURE, IF-ON, IF-OFF)\r
  77 # -------------------------------------\r
  78 # Expands according to the M4 (static) status of the feature.\r
  79 AC_DEFUN([DX_IF_FEATURE], [ifelse(DX_FEATURE_$1, ON, [$2], [$3])])\r
  80 \r
  81 # DX_REQUIRE_PROG(VARIABLE, PROGRAM)\r
  82 # ----------------------------------\r
  83 # Require the specified program to be found for the DX_CURRENT_FEATURE to work.\r
  84 AC_DEFUN([DX_REQUIRE_PROG], [\r
  85 AC_PATH_TOOL([$1], [$2])\r
  86 if test "$DX_FLAG_DX_CURRENT_FEATURE$$1" = 1; then\r
  87     AC_MSG_WARN([$2 not found - will not DX_CURRENT_DESCRIPTION])\r
  88     AC_SUBST([DX_FLAG_DX_CURRENT_FEATURE], 0)\r
  89 fi\r
  90 ])\r
  91 \r
  92 # DX_TEST_FEATURE(FEATURE)\r
  93 # ------------------------\r
  94 # Expand to a shell expression testing whether the feature is active.\r
  95 AC_DEFUN([DX_TEST_FEATURE], [test "$DX_FLAG_$1" = 1])\r
  96 \r
  97 # DX_CHECK_DEPEND(REQUIRED_FEATURE, REQUIRED_STATE)\r
  98 # -------------------------------------------------\r
  99 # Verify that a required features has the right state before trying to turn on\r
 100 # the DX_CURRENT_FEATURE.\r
 101 AC_DEFUN([DX_CHECK_DEPEND], [\r
 102 test "$DX_FLAG_$1" = "$2" \\r
 103 || AC_MSG_ERROR([doxygen-DX_CURRENT_FEATURE ifelse([$2], 1,\r
 104                             requires, contradicts) doxygen-DX_CURRENT_FEATURE])\r
 105 ])\r
 106 \r
 107 # DX_CLEAR_DEPEND(FEATURE, REQUIRED_FEATURE, REQUIRED_STATE)\r
 108 # ----------------------------------------------------------\r
 109 # Turn off the DX_CURRENT_FEATURE if the required feature is off.\r
 110 AC_DEFUN([DX_CLEAR_DEPEND], [\r
 111 test "$DX_FLAG_$1" = "$2" || AC_SUBST([DX_FLAG_DX_CURRENT_FEATURE], 0)\r
 112 ])\r
 113 \r
 114 \r
 115 # DX_FEATURE_ARG(FEATURE, DESCRIPTION,\r
 116 #                CHECK_DEPEND, CLEAR_DEPEND,\r
 117 #                REQUIRE, DO-IF-ON, DO-IF-OFF)\r
 118 # --------------------------------------------\r
 119 # Parse the command-line option controlling a feature. CHECK_DEPEND is called\r
 120 # if the user explicitly turns the feature on (and invokes DX_CHECK_DEPEND),\r
 121 # otherwise CLEAR_DEPEND is called to turn off the default state if a required\r
 122 # feature is disabled (using DX_CLEAR_DEPEND). REQUIRE performs additional\r
 123 # requirement tests (DX_REQUIRE_PROG). Finally, an automake flag is set and\r
 124 # DO-IF-ON or DO-IF-OFF are called according to the final state of the feature.\r
 125 AC_DEFUN([DX_ARG_ABLE], [\r
 126     AC_DEFUN([DX_CURRENT_FEATURE], [$1])\r
 127     AC_DEFUN([DX_FLAG_DX_CURRENT_FEATURE], [DX_FLAG_$1])\r
 128     AC_DEFUN([DX_CURRENT_DESCRIPTION], [$2])\r
 129     AC_ARG_ENABLE(doxygen-$1,\r
 130                   [AS_HELP_STRING(DX_IF_FEATURE([$1], [--disable-doxygen-$1],\r
 131                                                       [--enable-doxygen-$1]),\r
 132                                   DX_IF_FEATURE([$1], [don't $2], [$2]))],\r
 133                   [\r
 134 case "$enableval" in\r
 135 #(\r
 136 y|Y|yes|Yes|YES)\r
 137     AC_SUBST([DX_FLAG_$1], 1)\r
 138     $3\r
 139 ;; #(\r
 140 n|N|no|No|NO)\r
 141     AC_SUBST([DX_FLAG_$1], 0)\r
 142 ;; #(\r
 143 *)\r
 144     AC_MSG_ERROR([invalid value '$enableval' given to doxygen-$1])\r
 145 ;;\r
 146 esac\r
 147 ], [\r
 148 AC_SUBST([DX_FLAG_$1], [DX_IF_FEATURE([$1], 1, 0)])\r
 149 $4\r
 150 ])\r
 151 if DX_TEST_FEATURE([$1]); then\r
 152     $5\r
 153     :\r
 154 fi\r
 155 if DX_TEST_FEATURE([$1]); then\r
 156     AM_CONDITIONAL(DX_COND_$1, :)\r
 157     $6\r
 158     :\r
 159 else\r
 160     AM_CONDITIONAL(DX_COND_$1, false)\r
 161     $7\r
 162     :\r
 163 fi\r
 164 ])\r
 165 \r
 166 ## -------------- ##\r
 167 ## Public macros. ##\r
 168 ## -------------- ##\r
 169 \r
 170 # DX_XXX_FEATURE(DEFAULT_STATE)\r
 171 # -----------------------------\r
 172 AC_DEFUN([DX_DOXYGEN_FEATURE], [AC_DEFUN([DX_FEATURE_doc],  [$1])])\r
 173 AC_DEFUN([DX_MAN_FEATURE],     [AC_DEFUN([DX_FEATURE_man],  [$1])])\r
 174 AC_DEFUN([DX_HTML_FEATURE],    [AC_DEFUN([DX_FEATURE_html], [$1])])\r
 175 AC_DEFUN([DX_CHM_FEATURE],     [AC_DEFUN([DX_FEATURE_chm],  [$1])])\r
 176 AC_DEFUN([DX_CHI_FEATURE],     [AC_DEFUN([DX_FEATURE_chi],  [$1])])\r
 177 AC_DEFUN([DX_RTF_FEATURE],     [AC_DEFUN([DX_FEATURE_rtf],  [$1])])\r
 178 AC_DEFUN([DX_XML_FEATURE],     [AC_DEFUN([DX_FEATURE_xml],  [$1])])\r
 179 AC_DEFUN([DX_XML_FEATURE],     [AC_DEFUN([DX_FEATURE_xml],  [$1])])\r
 180 AC_DEFUN([DX_PDF_FEATURE],     [AC_DEFUN([DX_FEATURE_pdf],  [$1])])\r
 181 AC_DEFUN([DX_PS_FEATURE],      [AC_DEFUN([DX_FEATURE_ps],   [$1])])\r
 182 \r
 183 # DX_INIT_DOXYGEN(PROJECT, [CONFIG-FILE], [OUTPUT-DOC-DIR])\r
 184 # ---------------------------------------------------------\r
 185 # PROJECT also serves as the base name for the documentation files.\r
 186 # The default CONFIG-FILE is "Doxyfile" and OUTPUT-DOC-DIR is "doxygen-doc".\r
 187 AC_DEFUN([DX_INIT_DOXYGEN], [\r
 188 \r
 189 # Files:\r
 190 AC_SUBST([DX_PROJECT], [$1])\r
 191 AC_SUBST([DX_CONFIG], [ifelse([$2], [], Doxyfile, [$2])])\r
 192 AC_SUBST([DX_DOCDIR], [ifelse([$3], [], doxygen-doc, [$3])])\r
 193 \r
 194 # Environment variables used inside doxygen.cfg:\r
 195 DX_ENV_APPEND(SRCDIR, $srcdir)\r
 196 DX_ENV_APPEND(PROJECT, $DX_PROJECT)\r
 197 DX_ENV_APPEND(DOCDIR, $DX_DOCDIR)\r
 198 DX_ENV_APPEND(VERSION, $PACKAGE_VERSION)\r
 199 \r
 200 # Doxygen itself:\r
 201 DX_ARG_ABLE(doc, [generate any doxygen documentation],\r
 202             [],\r
 203             [],\r
 204             [DX_REQUIRE_PROG([DX_DOXYGEN], doxygen)\r
 205              DX_REQUIRE_PROG([DX_PERL], perl)],\r
 206             [DX_ENV_APPEND(PERL_PATH, $DX_PERL)])\r
 207 \r
 208 # Dot for graphics:\r
 209 DX_ARG_ABLE(dot, [generate graphics for doxygen documentation],\r
 210             [DX_CHECK_DEPEND(doc, 1)],\r
 211             [DX_CLEAR_DEPEND(doc, 1)],\r
 212             [DX_REQUIRE_PROG([DX_DOT], dot)],\r
 213             [DX_ENV_APPEND(HAVE_DOT, YES)\r
 214              DX_ENV_APPEND(DOT_PATH, [`DX_DIRNAME_EXPR($DX_DOT)`])],\r
 215             [DX_ENV_APPEND(HAVE_DOT, NO)])\r
 216 \r
 217 # Man pages generation:\r
 218 DX_ARG_ABLE(man, [generate doxygen manual pages],\r
 219             [DX_CHECK_DEPEND(doc, 1)],\r
 220             [DX_CLEAR_DEPEND(doc, 1)],\r
 221             [],\r
 222             [DX_ENV_APPEND(GENERATE_MAN, YES)],\r
 223             [DX_ENV_APPEND(GENERATE_MAN, NO)])\r
 224 \r
 225 # RTF file generation:\r
 226 DX_ARG_ABLE(rtf, [generate doxygen RTF documentation],\r
 227             [DX_CHECK_DEPEND(doc, 1)],\r
 228             [DX_CLEAR_DEPEND(doc, 1)],\r
 229             [],\r
 230             [DX_ENV_APPEND(GENERATE_RTF, YES)],\r
 231             [DX_ENV_APPEND(GENERATE_RTF, NO)])\r
 232 \r
 233 # XML file generation:\r
 234 DX_ARG_ABLE(xml, [generate doxygen XML documentation],\r
 235             [DX_CHECK_DEPEND(doc, 1)],\r
 236             [DX_CLEAR_DEPEND(doc, 1)],\r
 237             [],\r
 238             [DX_ENV_APPEND(GENERATE_XML, YES)],\r
 239             [DX_ENV_APPEND(GENERATE_XML, NO)])\r
 240 \r
 241 # (Compressed) HTML help generation:\r
 242 DX_ARG_ABLE(chm, [generate doxygen compressed HTML help documentation],\r
 243             [DX_CHECK_DEPEND(doc, 1)],\r
 244             [DX_CLEAR_DEPEND(doc, 1)],\r
 245             [DX_REQUIRE_PROG([DX_HHC], hhc)],\r
 246             [DX_ENV_APPEND(HHC_PATH, $DX_HHC)\r
 247              DX_ENV_APPEND(GENERATE_HTML, YES)\r
 248              DX_ENV_APPEND(GENERATE_HTMLHELP, YES)],\r
 249             [DX_ENV_APPEND(GENERATE_HTMLHELP, NO)])\r
 250 \r
 251 # Separate CHI file generation.\r
 252 DX_ARG_ABLE(chi, [generate doxygen separate compressed HTML help index file],\r
 253             [DX_CHECK_DEPEND(chm, 1)],\r
 254             [DX_CLEAR_DEPEND(chm, 1)],\r
 255             [],\r
 256             [DX_ENV_APPEND(GENERATE_CHI, YES)],\r
 257             [DX_ENV_APPEND(GENERATE_CHI, NO)])\r
 258 \r
 259 # Plain HTML pages generation:\r
 260 DX_ARG_ABLE(html, [generate doxygen plain HTML documentation],\r
 261             [DX_CHECK_DEPEND(doc, 1) DX_CHECK_DEPEND(chm, 0)],\r
 262             [DX_CLEAR_DEPEND(doc, 1) DX_CLEAR_DEPEND(chm, 0)],\r
 263             [],\r
 264             [DX_ENV_APPEND(GENERATE_HTML, YES)],\r
 265             [DX_TEST_FEATURE(chm) || DX_ENV_APPEND(GENERATE_HTML, NO)])\r
 266 \r
 267 # PostScript file generation:\r
 268 DX_ARG_ABLE(ps, [generate doxygen PostScript documentation],\r
 269             [DX_CHECK_DEPEND(doc, 1)],\r
 270             [DX_CLEAR_DEPEND(doc, 1)],\r
 271             [DX_REQUIRE_PROG([DX_LATEX], latex)\r
 272              DX_REQUIRE_PROG([DX_MAKEINDEX], makeindex)\r
 273              DX_REQUIRE_PROG([DX_DVIPS], dvips)\r
 274              DX_REQUIRE_PROG([DX_EGREP], egrep)])\r
 275 \r
 276 # PDF file generation:\r
 277 DX_ARG_ABLE(pdf, [generate doxygen PDF documentation],\r
 278             [DX_CHECK_DEPEND(doc, 1)],\r
 279             [DX_CLEAR_DEPEND(doc, 1)],\r
 280             [DX_REQUIRE_PROG([DX_PDFLATEX], pdflatex)\r
 281              DX_REQUIRE_PROG([DX_MAKEINDEX], makeindex)\r
 282              DX_REQUIRE_PROG([DX_EGREP], egrep)])\r
 283 \r
 284 # LaTeX generation for PS and/or PDF:\r
 285 if DX_TEST_FEATURE(ps) || DX_TEST_FEATURE(pdf); then\r
 286     AM_CONDITIONAL(DX_COND_latex, :)\r
 287     DX_ENV_APPEND(GENERATE_LATEX, YES)\r
 288 else\r
 289     AM_CONDITIONAL(DX_COND_latex, false)\r
 290     DX_ENV_APPEND(GENERATE_LATEX, NO)\r
 291 fi\r
 292 \r
 293 # Paper size for PS and/or PDF:\r
 294 AC_ARG_VAR(DOXYGEN_PAPER_SIZE,\r
 295            [a4wide (default), a4, letter, legal or executive])\r
 296 case "$DOXYGEN_PAPER_SIZE" in\r
 297 #(\r
 298 "")\r
 299     AC_SUBST(DOXYGEN_PAPER_SIZE, "")\r
 300 ;; #(\r
 301 a4wide|a4|letter|legal|executive)\r
 302     DX_ENV_APPEND(PAPER_SIZE, $DOXYGEN_PAPER_SIZE)\r
 303 ;; #(\r
 304 *)\r
 305     AC_MSG_ERROR([unknown DOXYGEN_PAPER_SIZE='$DOXYGEN_PAPER_SIZE'])\r
 306 ;;\r
 307 esac\r
 308 \r
 309 #For debugging:\r
 310 #echo DX_FLAG_doc=$DX_FLAG_doc\r
 311 #echo DX_FLAG_dot=$DX_FLAG_dot\r
 312 #echo DX_FLAG_man=$DX_FLAG_man\r
 313 #echo DX_FLAG_html=$DX_FLAG_html\r
 314 #echo DX_FLAG_chm=$DX_FLAG_chm\r
 315 #echo DX_FLAG_chi=$DX_FLAG_chi\r
 316 #echo DX_FLAG_rtf=$DX_FLAG_rtf\r
 317 #echo DX_FLAG_xml=$DX_FLAG_xml\r
 318 #echo DX_FLAG_pdf=$DX_FLAG_pdf\r
 319 #echo DX_FLAG_ps=$DX_FLAG_ps\r
 320 #echo DX_ENV=$DX_ENV\r
 321 ])\r