configure.in

   1 dnl Process this file with autoconf to produce a configure script.  -*- Autoconf
   2  -*-
   3
   4 dnl This file is a part of Geeqie project (http://www.geeqie.org/).
   5 dnl Copyright (C) 2008 - 2016 The Geeqie Team
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16
  17 AC_PREREQ(2.57)
  18 AC_INIT([geeqie], m4_esyscmd_s(git rev-parse --quiet --verify --short master), [geeqie-devel@lists.sourceforge.net], [], [http://www.geeqie.org/])
  19
  20 # Add -Werror to the default CFLAGS
  21 CFLAGS+=" -Werror -Wno-error=deprecated-declarations"
  22
  23 # Check for rightly dirs
  24 AC_CONFIG_SRCDIR([src/main.c])
  25
  26 AC_CONFIG_AUX_DIR(auxdir)
  27 # Require Automake 1.14 for %reldir% support
  28 AM_INIT_AUTOMAKE([1.14.1 subdir-objects])
  29
  30 AC_CONFIG_HEADER([config.h])
  31
  32 # Only for developers
  33 AM_MAINTAINER_MODE
  34
  35 AC_ARG_ENABLE(developer, [
  36 Development options:
  37 AC_HELP_STRING([--enable-developer], [turn on developers mode [default=no]])],
  38 [
  39   __IS_DEVELOPER=yes
  40 ],
  41 [
  42 if test "x${enable_developer}" != "xyes"
  43 then
  44   __IS_DEVELOPER=no
  45 else
  46   __IS_DEVELOPER=yes
  47 fi
  48 ])
  49
  50 DX_HTML_FEATURE(ON)
  51 DX_CHM_FEATURE(OFF)
  52 DX_CHI_FEATURE(OFF)
  53 DX_MAN_FEATURE(OFF)
  54 DX_RTF_FEATURE(OFF)
  55 DX_XML_FEATURE(OFF)
  56 DX_PDF_FEATURE(OFF)
  57 DX_PS_FEATURE(OFF)
  58
  59 DX_INIT_DOXYGEN($PACKAGE_NAME, doxygen.conf, doc/doxygen)
  60
  61 #  Debug support
  62 # ----------------------------------------------------------------------
  63
  64 dnl Debugging option
  65 dnl FIXME: official release convert default to 'no'
  66 dnl
  67
  68 AC_ARG_ENABLE([debug-flags], [
  69 Development options:
  70 AC_HELP_STRING([--enable-debug-flags], [use compiler flags for debugging [default=no]])], [],
  71 [
  72 if test "x${enable_developer}" != "xyes"
  73 then
  74   enable_debug_flags="no"
  75 else
  76   enable_debug_flags="yes"
  77 fi
  78 ])
  79
  80 AC_ARG_ENABLE([debug-log], [
  81 Development options:
  82 AC_HELP_STRING([--enable-debug-log], [enable debugging messages [default=yes]])], [], [enable_debug_log="yes"])
  83
  84 if test "x${enable_debug_flags}" != "xno"
  85 then
  86   if test "x${enable_developer}" = "xyes"
  87   then
  88     CXXFLAGS="${CXXFLAGS} -Wall"
  89     CFLAGS="${CFLAGS} -Wstrict-prototypes -Wall"
  90   fi
  91   __COMMONFLAGS="-g -O0 -Wextra -Wunused-value -Wunused-variable -Wunused-function -Wunused-label -Wcomment -Wmissing-braces -Wparentheses -Wreturn-type -Wswitch -Wstrict-aliasing -Wno-unused-parameter -Wformat -Wformat-security -DGQ_DEBUG_PATH_UTF8=1"
  92   CXXFLAGS="${CXXFLAGS} ${__COMMONFLAGS}"
  93   CFLAGS="${CFLAGS} ${__COMMONFLAGS} -Wimplicit-int -Werror-implicit-function-declaration"
  94   __IS_DEBUG_FLAGS=yes
  95 else
  96   __IS_DEBUG_FLAGS=no
  97 fi
  98
  99 if test "x${enable_debug_log}" != "xno"
 100 then
 101   AC_DEFINE(DEBUG,1,[Defined if Geeqie is compiled with debugging messages support])
 102   __IS_DEBUG_LOG=yes
 103 else
 104   __IS_DEBUG_LOG=no
 105 fi
 106
 107 AM_CONDITIONAL(DEBUG, test x$enable_debug_flags = xyes)
 108
 109 AC_ARG_ENABLE(deprecated, [
 110 AC_HELP_STRING([--enable-deprecated], [turn off checking of deprecated functions [default=yes]])], [],
 111 [
 112 if test "x${enable_developer}" != "xyes"
 113 then
 114   enable_deprecated="no"
 115 else
 116   enable_deprecated="yes"
 117 fi
 118 ])
 119
 120 if test "x${enable_deprecated}" != "xno"
 121 then
 122   CXXFLAGS="${CXXFLAGS} -DGTK_DISABLE_DEPRECATED=1 -DGDK_DISABLE_DEPRECATED=1 -DGDK_PIXBUF_DISABLE_DEPRECATED=1 -DG_DISABLE_DEPRECATED=1"
 123   CFLAGS="${CFLAGS} -DGTK_DISABLE_DEPRECATED=1 -DGDK_DISABLE_DEPRECATED=1 -DGDK_PIXBUF_DISABLE_DEPRECATED=1 -DG_DISABLE_DEPRECATED=1"
 124   __IS_DEPRECATED=yes
 125 else
 126   __IS_DEPRECATED=no
 127 fi
 128
 129
 130 AC_ISC_POSIX
 131 AC_PROG_CC
 132 AC_PROG_CXX
 133 AC_STDC_HEADERS
 134 AC_ARG_PROGRAM
 135 AC_SYS_LARGEFILE
 136 IT_PROG_INTLTOOL([0.35.0])
 137
 138
 139 dnl checks for functions
 140 AC_CHECK_FUNCS(strverscmp access fsync fflush)
 141
 142
 143 # Check target architecture
 144
 145 # Check for Win32
 146 AC_MSG_CHECKING([for some Win32 platform])
 147 case "$target_os" in
 148   mingw* | cygwin*)
 149     platform_win32=yes
 150     AC_DEFINE(PLATFORM_WIN32, 1, [Build on win32 OS])
 151     ;;
 152   *)
 153     platform_win32=no
 154     ;;
 155 esac
 156 AC_MSG_RESULT([$platform_win32])
 157 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 158
 159 AC_MSG_CHECKING([for native Win32])
 160 case "$target_os" in
 161   mingw*)
 162     os_win32=yes
 163     AC_DEFINE(OS_WIN32, 1, [Build on native win32 OS])
 164     os_unix=no
 165     PATHSEP=';'
 166     ;;
 167   *)
 168     os_win32=no
 169     os_unix=yes
 170     PATHSEP=':'
 171     ;;
 172 esac
 173 AC_MSG_RESULT([$os_win32])
 174 AC_SUBST(PATHSEP)
 175 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 176 AM_CONDITIONAL(OS_UNIX, test "$os_unix" = "yes")
 177
 178 if test "$os_win32" = "yes"; then
 179   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 180   AC_CHECK_TOOL(WINDRES, windres, :)
 181 else
 182   WINDRES=":"
 183 fi
 184
 185 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 186 AM_CONDITIONAL(HAVE_WINDRES, test "x$WINDRES" != "x:")
 187 AC_SUBST(WINDRES)
 188
 189 dnl reasonable guesses for where stuff is installed
 190 if test "x$prefix" = "xNONE"; then
 191   prefix="/usr/local"
 192 else
 193   prefix=$prefix
 194 fi
 195
 196 AM_PATH_GLIB_2_0(2.24.0,,AC_MSG_ERROR(GLIB >= 2.24.0 not installed.))
 197 AC_ARG_ENABLE([gtk3], AC_HELP_STRING([--disable-gtk3], [use gtk2 instead of gtk3]),[gtk3="${enableval}"], [gtk3=m4_ifdef([AM_PATH_GTK_3_0], [auto], [no])])
 198
 199 if test x$gtk3 == xyes; then
 200     AC_MSG_WARN("Gtk3 enabled")
 201     m4_ifdef([AM_PATH_GTK_3_0], [AM_PATH_GTK_3_0(3.0.0,,AC_MSG_ERROR(GTK+ >= 3.0.0 not installed.))])
 202 else
 203     if test x$gtk3 != xno; then
 204        AC_MSG_WARN("Gtk3 is preferred...")
 205        m4_ifdef([AM_PATH_GTK_3_0], [AM_PATH_GTK_3_0(3.0.0,,[gtk3=no])])
 206     fi
 207 fi
 208
 209 if test x$gtk3 == xno; then
 210     m4_ifdef([AM_PATH_GTK_2_0], [AM_PATH_GTK_2_0(2.20.0,,AC_MSG_ERROR(GTK+ >= 2.20.0 not installed.))])
 211     true
 212 fi
 213
 214 threads="auto"
 215 AC_ARG_ENABLE([threads],
 216   AC_HELP_STRING([--disable-threads], [disable thread support]), [threads="${enableval}"])
 217
 218 have_gthread="no"
 219 if test "x${threads}" != "xno" ; then
 220   PKG_CHECK_MODULES(GTHREAD, [gthread-2.0], have_gthread="yes", [AC_MSG_WARN("No thread support in glib")])
 221 fi
 222
 223 if test "x$have_gthread" != "xno"; then
 224         AC_DEFINE(HAVE_GTHREAD, 1, Define if you have gthread library)
 225         GLIB_CFLAGS="$GTHREAD_CFLAGS"
 226         GLIB_LIBS="$GTHREAD_LIBS"
 227 fi
 228
 229
 230 AC_PATH_PROGS(GDK_PIXBUF_CSOURCE, "gdk-pixbuf-csource")
 231 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
 232
 233 AC_ARG_WITH(readmedir, [  --with-readmedir=DIR    install path for readme files],
 234             readmedir=$withval, readmedir="$prefix/share/doc/geeqie-$VERSION")
 235 AC_ARG_WITH(htmldir, [  --with-htmldir=DIR      install path for html files],
 236             htmldir=$withval, htmldir="$readmedir/html")
 237
 238 AC_DEFINE_UNQUOTED(GQ_HELPDIR, "$readmedir", [Location of documentation files])
 239 AC_DEFINE_UNQUOTED(GQ_HTMLDIR, "$htmldir", [Location of html documentation])
 240
 241 AC_PATH_PROG(GNOME_DOC_TOOL, gnome-doc-tool)
 242
 243 AC_SUBST(readmedir)
 244 AC_SUBST(htmldir)
 245
 246 eval "eval appdir=${datadir}/${PACKAGE}"
 247 AC_DEFINE_UNQUOTED([GQ_APP_DIR], "$appdir", [Location of application data])
 248 AC_SUBST(appdir)
 249
 250 eval "eval gq_bindir=${prefix}/lib/${PACKAGE}"
 251 AC_DEFINE_UNQUOTED([GQ_BIN_DIR], "$gq_bindir", [Location of helper scripts and executables])
 252 AC_SUBST(gq_bindir)
 253
 254 #  LIRC support
 255 # ----------------------------------------------------------------------
 256
 257 dnl Check for LIRC client support
 258 AC_MSG_CHECKING(if LIRC support is enabled)
 259 lirc=no
 260 AC_ARG_ENABLE([lirc],
 261   AC_HELP_STRING([--disable-lirc], [disable lirc support (auto)]),
 262 [
 263 if test "x${enableval}" = "xyes" -a "x$GCC" = "xyes"; then
 264   AC_MSG_RESULT(yes)
 265   lirc=yes
 266 else
 267   AC_MSG_RESULT(no)
 268   lirc=no
 269 fi], AC_MSG_RESULT(no))
 270
 271
 272 AC_ARG_WITH(lirc-prefix,
 273 [  --with-lirc-prefix=PATH Prefix where LIRC is installed],
 274 [
 275 for dir in `echo "$withval" | tr : ' '`; do
 276   if test -d $dir/lib; then CXXFLAGS="$CXXFLAGS -L$dir/lib"; fi
 277   if test -d $dir/include; then CXXFLAGS="$CXXFLAGS -I$dir/include"; fi
 278   done
 279 ])
 280
 281 HAVE_LIRC=no
 282 if test "x${lirc}" != "xno" ; then
 283   AC_CHECK_HEADER(lirc/lirc_client.h,
 284     [AC_CHECK_LIB(lirc_client,lirc_init,[HAVE_LIRC=yes;LIBS=-llirc_client $LIBS;AC_DEFINE([HAVE_LIRC],[],[Define to 1 if LIRC must be used])],,)],)
 285 fi
 286 AM_CONDITIONAL(HAVE_LIRC, [test "x$HAVE_LIRC" = xyes])
 287
 288
 289 #  LCMS support
 290 # ----------------------------------------------------------------------
 291
 292 AC_ARG_ENABLE([lcms],
 293   AC_HELP_STRING([--disable-lcms], [disable lcms support]),
 294     [liblcms=$enableval], [liblcms=auto])
 295
 296 if test "x${liblcms}" != "xno"; then
 297   PKG_CHECK_MODULES(LCMS, [lcms2 >= 2.0],
 298     [
 299       HAVE_LCMS=yes
 300       AC_DEFINE(HAVE_LCMS, 1, [define to enable use of color profiles with lcms])
 301       AC_DEFINE(HAVE_LCMS2, 1, [lcms2 is used])
 302     ],
 303     [
 304     PKG_CHECK_MODULES(LCMS, [lcms >= 1.14],
 305       [
 306         HAVE_LCMS=yes
 307         AC_DEFINE(HAVE_LCMS, 1, [define to enable use of color profiles with lcms])
 308       ],
 309       [
 310         HAVE_LCMS=no
 311         AC_MSG_WARN([$LCMS_PKG_ERRORS])
 312       ])
 313     ])
 314 else
 315   HAVE_LCMS=disabled
 316 fi
 317
 318 AM_CONDITIONAL(HAVE_LCMS, [test "x$HAVE_LCMS" = xyes])
 319 AC_SUBST(LCMS_CFLAGS)
 320 AC_SUBST(LCMS_LIBS)
 321
 322 #  libjpeg support
 323 # ----------------------------------------------------------------------
 324
 325 AC_ARG_ENABLE([jpeg],
 326   AC_HELP_STRING([--disable-jpeg], [disable direct jpeg support]),
 327     [libjpeg=$enableval], [libjpeg=auto])
 328
 329 if test "x${libjpeg}" != "xno"; then
 330   AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 331       HAVE_JPEG=yes
 332       JPEG_LIBS=-ljpeg
 333       AC_DEFINE(HAVE_JPEG, 1, [define to enable use of custom jpeg loader]),
 334       HAVE_JPEG=no)
 335 else
 336   HAVE_JPEG=disabled
 337 fi
 338
 339 AM_CONDITIONAL(HAVE_JPEG, [test "x$HAVE_JPEG" = xyes])
 340 AC_SUBST(JPEG_CFLAGS)
 341 AC_SUBST(JPEG_LIBS)
 342
 343
 344 #  libtiff support
 345 # ----------------------------------------------------------------------
 346
 347 AC_ARG_ENABLE([tiff],
 348   AC_HELP_STRING([--disable-tiff], [disable direct tiff support]),
 349     [libtiff=$enableval], [libtiff=auto])
 350
 351 if test "x${libtiff}" != "xno"; then
 352   AC_CHECK_LIB(tiff, TIFFClientOpen,
 353       HAVE_TIFF=yes
 354       TIFF_LIBS=-ltiff
 355       AC_DEFINE(HAVE_TIFF, 1, [define to enable use of custom tiff loader]),
 356       HAVE_TIFF=no)
 357 else
 358   HAVE_TIFF=disabled
 359 fi
 360
 361 AM_CONDITIONAL(HAVE_TIFF, [test "x$HAVE_TIFF" = xyes])
 362 AC_SUBST(TIFF_CFLAGS)
 363 AC_SUBST(TIFF_LIBS)
 364
 365
 366 #  Exiv2 support
 367 # ----------------------------------------------------------------------
 368
 369 AC_ARG_ENABLE([exiv2],
 370   AC_HELP_STRING([--disable-exiv2], [disable exiv2 support]),
 371     [libexiv2=$enableval], [libexiv2=auto])
 372
 373 if test "x${libexiv2}" != "xno"; then
 374   PKG_CHECK_MODULES(EXIV2, [exiv2 >= 0.11],
 375     [
 376       HAVE_EXIV2=yes
 377       AC_DEFINE(HAVE_EXIV2, 1, [define to enable exiv2 support])
 378     ],
 379     [
 380       HAVE_EXIV2=no
 381       AC_MSG_WARN([$EXIV2_PKG_ERRORS])
 382     ])
 383 else
 384   HAVE_EXIV2=disabled
 385 fi
 386
 387 AM_CONDITIONAL(HAVE_EXIV2, [test "x$HAVE_EXIV2" = xyes])
 388 AC_SUBST(EXIV2_CFLAGS)
 389 AC_SUBST(EXIV2_LIBS)
 390
 391
 392 #  Gettext support
 393 # ----------------------------------------------------------------------
 394
 395 dnl Set of available languages
 396 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 397 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 398
 399 GETTEXT_PACKAGE=$PACKAGE
 400 AC_SUBST(GETTEXT_PACKAGE)
 401 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${GETTEXT_PACKAGE}"],[Name of gettext file])
 402 AM_GLIB_GNU_GETTEXT
 403 AM_GLIB_DEFINE_LOCALEDIR(GQ_LOCALEDIR)
 404
 405 AC_SUBST(CFLAGS)
 406 AC_SUBST(CXXFLAGS)
 407 AC_SUBST(CPPFLAGS)
 408 AC_SUBST(LDFLAGS)
 409
 410
 411 #  clutter and champlain support
 412 # ----------------------------------------------------------------------
 413
 414 AC_ARG_ENABLE([map],
 415   AC_HELP_STRING([--enable-map], [enable map support]),
 416     [libgps=$enableval], [libgps=no])
 417
 418 AC_ARG_ENABLE([gpu-accel],
 419   AC_HELP_STRING([--enable-gpu-accel], [enable GPU acceleration support - experimental]),
 420     [libclutter=$enableval], [libclutter=auto])
 421
 422 if test "x${libclutter}" = "xyes" -o "x${libgps}" = "xyes"; then
 423     if test "x${libclutter}" != "xno" -a "x${gtk3}" != "xno"; then
 424       PKG_CHECK_MODULES(CLUTTER, [clutter-1.0 >= 1.0],
 425         [
 426           PKG_CHECK_MODULES(CLUTTER_GTK, [clutter-gtk-1.0 >= 1.0],
 427             [
 428               HAVE_CLUTTER=yes
 429               AC_DEFINE(HAVE_CLUTTER, 1, [define to enable use of clutter library])
 430             ],
 431             [
 432               HAVE_CLUTTER=no
 433               AC_MSG_WARN([$CLUTTER_GTK_PKG_ERRORS])
 434             ])
 435         ],
 436         [
 437           HAVE_CLUTTER=no
 438           AC_MSG_WARN([$CLUTTER_PKG_ERRORS])
 439         ])
 440     else
 441       HAVE_CLUTTER=disabled
 442     fi
 443 else
 444   HAVE_CLUTTER=disabled
 445 fi
 446
 447 AC_SUBST(CLUTTER_CFLAGS)
 448 AC_SUBST(CLUTTER_LIBS)
 449 AC_SUBST(CLUTTER_GTK_CFLAGS)
 450 AC_SUBST(CLUTTER_GTK_LIBS)
 451
 452
 453 #  Libchamplain support - used for map facility
 454 # ----------------------------------------------------------------------
 455
 456 if test "x${libgps}" = "xyes" -a "x${HAVE_CLUTTER}" = "xyes"; then
 457     if test "x${gtk3}" != "xno"; then
 458       PKG_CHECK_MODULES(LIBCHAMPLAIN, [champlain-0.12 >= 0.12],
 459         [
 460           HAVE_LIBCHAMPLAIN=yes
 461           AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [define to enable use of maps])
 462         ],
 463         [
 464           HAVE_LIBCHAMPLAIN=no
 465           AC_MSG_WARN([$LIBCHAMPLAIN_PKG_ERRORS])
 466         ])
 467     else
 468       HAVE_LIBCHAMPLAIN=disabled
 469     fi
 470 else
 471   HAVE_LIBCHAMPLAIN=disabled
 472 fi
 473
 474 if test "x${libgps}" = "xyes" -a "x${HAVE_LIBCHAMPLAIN}" = "xyes" ; then
 475   PKG_CHECK_MODULES(LIBCHAMPLAIN_GTK, [champlain-gtk-0.12 >= 0.12],
 476     [
 477       HAVE_LIBCHAMPLAIN_GTK=yes
 478       AC_DEFINE(HAVE_LIBCHAMPLAIN_GTK, 1, [define to enable use of maps])
 479     ],
 480     [
 481       HAVE_LIBCHAMPLAIN_GTK=no
 482       AC_MSG_WARN([$LIBCHAMPLAIN_GTK_PKG_ERRORS])
 483     ])
 484 else
 485   HAVE_LIBCHAMPLAIN_GTK=disabled
 486 fi
 487
 488 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN_GTK, [test "x$HAVE_LIBCHAMPLAIN_GTK" = xyes])
 489 AC_SUBST(LIBCHAMPLAIN_GTK_CFLAGS)
 490 AC_SUBST(LIBCHAMPLAIN_GTK_LIBS)
 491
 492 #  Lua support
 493 # ----------------------------------------------------------------------
 494
 495 AC_ARG_ENABLE([lua],
 496   AC_HELP_STRING([--disable-lua], [disable lua support]),
 497     [liblua=$enableval], [liblua=auto])
 498
 499 if test "x${liblua}" != "xno"; then
 500   PKG_CHECK_MODULES(LUA, lua5.1 >= 5.1,
 501     [
 502       HAVE_LUA=yes
 503       AC_DEFINE(HAVE_LUA, 1, [define to enable lua support])
 504     ],
 505     [
 506       HAVE_LUA=no
 507       AC_MSG_WARN([$LUA_PKG_ERRORS])
 508     ])
 509 else
 510   HAVE_LUA=disabled
 511 fi
 512
 513 AM_CONDITIONAL(HAVE_LUA, [test "x$HAVE_LUA" = xyes])
 514 AC_SUBST(LUA_CFLAGS)
 515 AC_SUBST(LUA_LIBS)
 516
 517 # ----------------------------------------------------------------------
 518
 519 AH_TOP([
 520 /** \file
 521  * \short autogenerated definition by autoheader.
 522  * \author Bruclik
 523  */
 524
 525 /*
 526  *  This file is a part of Geeqie project (http://www.geeqie.org/).
 527  *  Copyright (C) 2008 - 2016 The Geeqie Team
 528  *
 529  *  This program is free software; you can redistribute it and/or modify
 530  *  it under the terms of the GNU General Public License as published by
 531  *  the Free Software Foundation; either version 2 of the License, or
 532  *  (at your option) any later version.
 533  *
 534  *  This program is distributed in the hope that it will be useful,
 535  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 536  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 537  *  GNU General Public License for more details.
 538  */
 539
 540 #ifndef _INCLUDE_CONFIG_H
 541 #define _INCLUDE_CONFIG_H
 542 ])
 543
 544 AH_BOTTOM([#endif])
 545
 546 dnl Write the output
 547 dnl
 548
 549 AC_CONFIG_FILES([
 550     Makefile
 551     src/Makefile
 552     src/icons/Makefile
 553     src/icons/svg/Makefile
 554     po/Makefile.in
 555     doc/Makefile
 556     plugins/Makefile
 557     plugins/symlink/Makefile
 558     plugins/rotate/Makefile
 559     plugins/ufraw/Makefile
 560     plugins/import/Makefile
 561     geeqie.spec
 562 ])
 563
 564 AC_OUTPUT
 565 dnl Print the results
 566 dnl
 567
 568 cat > config.report << END
 569
 570      Config results:
 571     -=-=-=-=-=-=-=-=-
 572
 573 Package:
 574   Name:          $PACKAGE_NAME
 575   Version:       $PACKAGE_VERSION
 576
 577 Architecture:
 578   UNIX:          $os_unix
 579   Win32:         $platform_win32 (native: $os_win32)
 580
 581 Flags:
 582   Geeqie:        $GQ_CFLAGS
 583   DEFS:          $DEFS
 584   CPPFLAGS:      $__CPPFLAGS
 585   CFLAGS:        $CFLAGS
 586   CXXFLAGS:      $CXXFLAGS
 587   Gtk:           $GTK_CFLAGS
 588   Glib:          $GLIB_CFLAGS
 589   Thread:        $GTHREAD_LIBS
 590   Others:        $JPEG_LIBS $TIFF_LIBS $LCMS_LIBS $EXIV2_LIBS $CLUTTER_LIBS $CLUTTER_GTK_LIBS $LIBCHAMPLAIN_LIBS $LIBCHAMPLAIN_GTK_LIBS $LUA_LIBS
 591
 592 Localization:
 593   NLS support:   $USE_NLS
 594   LINGUAS:       $LINGUAS
 595
 596 Settings:
 597   Developer:     $__IS_DEVELOPER
 598   Debug flags:   $__IS_DEBUG_FLAGS
 599   Debug log:     $__IS_DEBUG_LOG
 600   Deprecated:    $__IS_DEPRECATED
 601
 602 Support:
 603   LCMS:          $HAVE_LCMS
 604   Exiv2:         $HAVE_EXIV2
 605   Lirc:          $HAVE_LIRC
 606   Clutter:       $HAVE_CLUTTER
 607   Libchamplain:         $HAVE_LIBCHAMPLAIN
 608   Libchamplain-gtk:     $HAVE_LIBCHAMPLAIN_GTK
 609   Lua:           $HAVE_LUA
 610
 611 Documentation:
 612   Doxygen:       $DX_DOXYGEN
 613   doc-tool:      $GNOME_DOC_TOOL
 614
 615 END
 616
 617 cat config.report
 618 cat <<EOF
 619
 620   Now you can type "make" to build Geeqie
 621   (or you take blue pill and the story ends :)
 622
 623 EOF
 624