configure.in

   1 dnl Process this file with autoconf to produce a configure script.  -*- Autoconf
   2  -*-
   3
   4 dnl This file is a part of Geeqie project (http://geeqie.sourceforge.net/).
   5 dnl Copyright (C) 2008 - 2012 The Geeqie Team
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16
  17 AC_PREREQ(2.57)
  18 AC_INIT(geeqie, 1.1, geeqie-devel@lists.sourceforge.net)
  19
  20 # Check for rightly dirs
  21 AC_CONFIG_SRCDIR([src/main.c])
  22
  23 AC_CONFIG_AUX_DIR(auxdir)
  24 AM_INIT_AUTOMAKE
  25
  26 AC_CONFIG_HEADER([config.h])
  27
  28 # Only for developers
  29 AM_MAINTAINER_MODE
  30
  31 AC_ARG_ENABLE(developer, [
  32 Development options:
  33 AC_HELP_STRING([--enable-developer], [turn on developers mode [default=no]])],
  34 [
  35   __IS_DEVELOPER=yes
  36 ],
  37 [
  38 if test "x${enable_developer}" != "xyes"
  39 then
  40   __IS_DEVELOPER=no
  41 else
  42   __IS_DEVELOPER=yes
  43 fi
  44 ])
  45
  46 DX_HTML_FEATURE(ON)
  47 DX_CHM_FEATURE(OFF)
  48 DX_CHI_FEATURE(OFF)
  49 DX_MAN_FEATURE(OFF)
  50 DX_RTF_FEATURE(OFF)
  51 DX_XML_FEATURE(OFF)
  52 DX_PDF_FEATURE(OFF)
  53 DX_PS_FEATURE(OFF)
  54
  55 DX_INIT_DOXYGEN($PACKAGE_NAME, doxygen.conf, doc/doxygen)
  56
  57 #  Debug support
  58 # ----------------------------------------------------------------------
  59
  60 dnl Debugging option
  61 dnl FIXME: official release convert default to 'no'
  62 dnl
  63
  64 AC_ARG_ENABLE([debug-flags], [
  65 Development options:
  66 AC_HELP_STRING([--enable-debug-flags], [use compiler flags for debugging [default=no]])], [],
  67 [
  68 if test "x${enable_developer}" != "xyes"
  69 then
  70   enable_debug_flags="no"
  71 else
  72   enable_debug_flags="yes"
  73 fi
  74 ])
  75
  76 AC_ARG_ENABLE([debug-log], [
  77 Development options:
  78 AC_HELP_STRING([--enable-debug-log], [enable debugging messages [default=yes]])], [], [enable_debug_log="yes"])
  79
  80 if test "x${enable_debug_flags}" != "xno"
  81 then
  82   if test "x${enable_developer}" = "xyes"
  83   then
  84     CXXFLAGS="${CXXFLAGS} -Wall"
  85     CFLAGS="${CFLAGS} -Wstrict-prototypes -Wall"
  86   fi
  87   __COMMONFLAGS="-g -O0 -Wextra -Wunused-value -Wunused-variable -Wunused-function -Wunused-label -Wcomment -Wmissing-braces -Wparentheses -Wreturn-type -Wswitch -Wstrict-aliasing -Wno-unused-parameter -Wformat -Wformat-security -DGQ_DEBUG_PATH_UTF8=1"
  88   CXXFLAGS="${CXXFLAGS} ${__COMMONFLAGS}"
  89   CFLAGS="${CFLAGS} ${__COMMONFLAGS} -Wimplicit-int -Werror-implicit-function-declaration"
  90   __IS_DEBUG_FLAGS=yes
  91 else
  92   __IS_DEBUG_FLAGS=no
  93 fi
  94
  95 if test "x${enable_debug_log}" != "xno"
  96 then
  97   AC_DEFINE(DEBUG,1,[Defined if Geeqie is compiled with debugging messages support])
  98   __IS_DEBUG_LOG=yes
  99 else
 100   __IS_DEBUG_LOG=no
 101 fi
 102
 103 AM_CONDITIONAL(DEBUG, test x$enable_debug_flags = xyes)
 104
 105 AC_ARG_ENABLE(deprecated, [
 106 AC_HELP_STRING([--enable-deprecated], [turn off checking of deprecated functions [default=yes]])], [],
 107 [
 108 if test "x${enable_developer}" != "xyes"
 109 then
 110   enable_deprecated="no"
 111 else
 112   enable_deprecated="yes"
 113 fi
 114 ])
 115
 116 if test "x${enable_deprecated}" != "xno"
 117 then
 118   CXXFLAGS="${CXXFLAGS} -DGTK_DISABLE_DEPRECATED=1 -DGDK_DISABLE_DEPRECATED=1 -DGDK_PIXBUF_DISABLE_DEPRECATED=1 -DG_DISABLE_DEPRECATED=1"
 119   CFLAGS="${CFLAGS} -DGTK_DISABLE_DEPRECATED=1 -DGDK_DISABLE_DEPRECATED=1 -DGDK_PIXBUF_DISABLE_DEPRECATED=1 -DG_DISABLE_DEPRECATED=1"
 120   __IS_DEPRECATED=yes
 121 else
 122   __IS_DEPRECATED=no
 123 fi
 124
 125
 126 AC_ISC_POSIX
 127 AC_PROG_CC
 128 AC_PROG_CXX
 129 AC_STDC_HEADERS
 130 AC_ARG_PROGRAM
 131 AC_SYS_LARGEFILE
 132 IT_PROG_INTLTOOL([0.35.0])
 133
 134
 135 dnl checks for functions
 136 AC_CHECK_FUNCS(strverscmp access fsync fflush)
 137
 138
 139 # Check target architecture
 140
 141 # Check for Win32
 142 AC_MSG_CHECKING([for some Win32 platform])
 143 case "$target_os" in
 144   mingw* | cygwin*)
 145     platform_win32=yes
 146     AC_DEFINE(PLATFORM_WIN32, 1, [Build on win32 OS])
 147     ;;
 148   *)
 149     platform_win32=no
 150     ;;
 151 esac
 152 AC_MSG_RESULT([$platform_win32])
 153 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 154
 155 AC_MSG_CHECKING([for native Win32])
 156 case "$target_os" in
 157   mingw*)
 158     os_win32=yes
 159     AC_DEFINE(OS_WIN32, 1, [Build on native win32 OS])
 160     os_unix=no
 161     PATHSEP=';'
 162     ;;
 163   *)
 164     os_win32=no
 165     os_unix=yes
 166     PATHSEP=':'
 167     ;;
 168 esac
 169 AC_MSG_RESULT([$os_win32])
 170 AC_SUBST(PATHSEP)
 171 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 172 AM_CONDITIONAL(OS_UNIX, test "$os_unix" = "yes")
 173
 174 if test "$os_win32" = "yes"; then
 175   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 176   AC_CHECK_TOOL(WINDRES, windres, :)
 177 else
 178   WINDRES=":"
 179 fi
 180
 181 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 182 AM_CONDITIONAL(HAVE_WINDRES, test "x$WINDRES" != "x:")
 183 AC_SUBST(WINDRES)
 184
 185 dnl reasonable guesses for where stuff is installed
 186 if test "x$prefix" = "xNONE"; then
 187   prefix="/usr/local"
 188 else
 189   prefix=$prefix
 190 fi
 191
 192 AM_PATH_GLIB_2_0(2.4.0,,AC_MSG_ERROR(GLIB >= 2.4.0 not installed.))
 193 AC_ARG_ENABLE([gtk3], AC_HELP_STRING([--disable-gtk3], [use gtk2 instead of gtk3]),[gtk3="${enableval}"], [gtk3=m4_ifdef([AM_PATH_GTK_3_0], [auto], [no])])
 194
 195 if test x$gtk3 == xyes; then
 196     AC_MSG_WARN("Gtk3 enabled")
 197     m4_ifdef([AM_PATH_GTK_3_0], [AM_PATH_GTK_3_0(3.0.0,,AC_MSG_ERROR(GTK+ >= 3.0.0 not installed.))])
 198 else
 199     if test x$gtk3 != xno; then
 200        AC_MSG_WARN("Gtk3 is preferred...")
 201        m4_ifdef([AM_PATH_GTK_3_0], [AM_PATH_GTK_3_0(3.0.0,,[gtk3=no])])
 202     fi
 203 fi
 204
 205 if test x$gtk3 == xno; then
 206     m4_ifdef([AM_PATH_GTK_2_0], [AM_PATH_GTK_2_0(2.20.0,,AC_MSG_ERROR(GTK+ >= 2.12.0 not installed.))])
 207     true
 208 fi
 209
 210 threads="auto"
 211 AC_ARG_ENABLE([threads],
 212   AC_HELP_STRING([--disable-threads], [disable thread support]), [threads="${enableval}"])
 213
 214 have_gthread="no"
 215 if test "x${threads}" != "xno" ; then
 216   PKG_CHECK_MODULES(GTHREAD, [gthread-2.0], have_gthread="yes", [AC_MSG_WARN("No thread support in glib")])
 217 fi
 218
 219 if test "x$have_gthread" != "xno"; then
 220         AC_DEFINE(HAVE_GTHREAD, 1, Define if you have gthread library)
 221         GLIB_CFLAGS="$GTHREAD_CFLAGS"
 222         GLIB_LIBS="$GTHREAD_LIBS"
 223 fi
 224
 225
 226 AC_PATH_PROGS(GDK_PIXBUF_CSOURCE, "gdk-pixbuf-csource")
 227 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
 228
 229 AC_ARG_WITH(readmedir, [  --with-readmedir=DIR    install path for readme files],
 230             readmedir=$withval, readmedir="$prefix/share/doc/geeqie-$VERSION")
 231 AC_ARG_WITH(htmldir, [  --with-htmldir=DIR      install path for html files],
 232             htmldir=$withval, htmldir="$readmedir/html")
 233
 234 AC_DEFINE_UNQUOTED(GQ_HELPDIR, "$readmedir", [Location of documentation files])
 235 AC_DEFINE_UNQUOTED(GQ_HTMLDIR, "$htmldir", [Location of html documentation])
 236
 237 AC_PATH_PROG(GNOME_DOC_TOOL, gnome-doc-tool)
 238
 239 AC_SUBST(readmedir)
 240 AC_SUBST(htmldir)
 241
 242 eval "eval appdir=${datadir}/${PACKAGE}"
 243 AC_DEFINE_UNQUOTED([GQ_APP_DIR], "$appdir", [Location of application data])
 244 AC_SUBST(appdir)
 245
 246 eval "eval gq_bindir=${prefix}/lib/${PACKAGE}"
 247 AC_DEFINE_UNQUOTED([GQ_BIN_DIR], "$gq_bindir", [Location of helper scripts and executables])
 248 AC_SUBST(gq_bindir)
 249
 250 #  LIRC support
 251 # ----------------------------------------------------------------------
 252
 253 dnl Check for LIRC client support
 254 AC_MSG_CHECKING(if LIRC support is enabled)
 255 lirc=no
 256 AC_ARG_ENABLE([lirc],
 257   AC_HELP_STRING([--disable-lirc], [disable lirc support (auto)]),
 258 [
 259 if test "x${enableval}" = "xyes" -a "x$GCC" = "xyes"; then
 260   AC_MSG_RESULT(yes)
 261   lirc=yes
 262 else
 263   AC_MSG_RESULT(no)
 264   lirc=no
 265 fi], AC_MSG_RESULT(no))
 266
 267
 268 AC_ARG_WITH(lirc-prefix,
 269 [  --with-lirc-prefix=PATH Prefix where LIRC is installed],
 270 [
 271 for dir in `echo "$withval" | tr : ' '`; do
 272   if test -d $dir/lib; then CXXFLAGS="$CXXFLAGS -L$dir/lib"; fi
 273   if test -d $dir/include; then CXXFLAGS="$CXXFLAGS -I$dir/include"; fi
 274   done
 275 ])
 276
 277 HAVE_LIRC=no
 278 if test "x${lirc}" != "xno" ; then
 279   AC_CHECK_HEADER(lirc/lirc_client.h,
 280     [AC_CHECK_LIB(lirc_client,lirc_init,[HAVE_LIRC=yes;LIBS=-llirc_client $LIBS;AC_DEFINE([HAVE_LIRC],[],[Define to 1 if LIRC must be used])],,)],)
 281 fi
 282 AM_CONDITIONAL(HAVE_LIRC, [test "x$HAVE_LIRC" = xyes])
 283
 284
 285 #  LCMS support
 286 # ----------------------------------------------------------------------
 287
 288 AC_ARG_ENABLE([lcms],
 289   AC_HELP_STRING([--disable-lcms], [disable lcms support]),
 290     [liblcms=$enableval], [liblcms=auto])
 291
 292 if test "x${liblcms}" != "xno"; then
 293   PKG_CHECK_MODULES(LCMS, [lcms >= 1.14],
 294     [
 295       HAVE_LCMS=yes
 296       AC_DEFINE(HAVE_LCMS, 1, [define to enable use of color profiles with lcms])
 297     ],
 298     [
 299       HAVE_LCMS=no
 300       AC_MSG_WARN([$LCMS_PKG_ERRORS])
 301     ])
 302 else
 303   HAVE_LCMS=disabled
 304 fi
 305
 306 AM_CONDITIONAL(HAVE_LCMS, [test "x$HAVE_LCMS" = xyes])
 307 AC_SUBST(LCMS_CFLAGS)
 308 AC_SUBST(LCMS_LIBS)
 309
 310 #  libjpeg support
 311 # ----------------------------------------------------------------------
 312
 313 AC_ARG_ENABLE([jpeg],
 314   AC_HELP_STRING([--disable-jpeg], [disable direct jpeg support]),
 315     [libjpeg=$enableval], [libjpeg=auto])
 316
 317 if test "x${libjpeg}" != "xno"; then
 318   AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 319       HAVE_JPEG=yes
 320       JPEG_LIBS=-ljpeg
 321       AC_DEFINE(HAVE_JPEG, 1, [define to enable use of custom jpeg loader]),
 322       HAVE_JPEG=no)
 323 else
 324   HAVE_JPEG=disabled
 325 fi
 326
 327 AM_CONDITIONAL(HAVE_JPEG, [test "x$HAVE_JPEG" = xyes])
 328 AC_SUBST(JPEG_CFLAGS)
 329 AC_SUBST(JPEG_LIBS)
 330
 331
 332 #  libtiff support
 333 # ----------------------------------------------------------------------
 334
 335 AC_ARG_ENABLE([tiff],
 336   AC_HELP_STRING([--disable-tiff], [disable direct tiff support]),
 337     [libtiff=$enableval], [libtiff=auto])
 338
 339 if test "x${libtiff}" != "xno"; then
 340   AC_CHECK_LIB(tiff, TIFFClientOpen,
 341       HAVE_TIFF=yes
 342       TIFF_LIBS=-ltiff
 343       AC_DEFINE(HAVE_TIFF, 1, [define to enable use of custom tiff loader]),
 344       HAVE_TIFF=no)
 345 else
 346   HAVE_TIFF=disabled
 347 fi
 348
 349 AM_CONDITIONAL(HAVE_TIFF, [test "x$HAVE_TIFF" = xyes])
 350 AC_SUBST(TIFF_CFLAGS)
 351 AC_SUBST(TIFF_LIBS)
 352
 353
 354 #  Exiv2 support
 355 # ----------------------------------------------------------------------
 356
 357 AC_ARG_ENABLE([exiv2],
 358   AC_HELP_STRING([--disable-exiv2], [disable exiv2 support]),
 359     [libexiv2=$enableval], [libexiv2=auto])
 360
 361 if test "x${libexiv2}" != "xno"; then
 362   PKG_CHECK_MODULES(EXIV2, [exiv2 >= 0.11],
 363     [
 364       HAVE_EXIV2=yes
 365       AC_DEFINE(HAVE_EXIV2, 1, [define to enable exiv2 support])
 366     ],
 367     [
 368       HAVE_EXIV2=no
 369       AC_MSG_WARN([$EXIV2_PKG_ERRORS])
 370     ])
 371 else
 372   HAVE_EXIV2=disabled
 373 fi
 374
 375 AM_CONDITIONAL(HAVE_EXIV2, [test "x$HAVE_EXIV2" = xyes])
 376 AC_SUBST(EXIV2_CFLAGS)
 377 AC_SUBST(EXIV2_LIBS)
 378
 379
 380 #  Gettext support
 381 # ----------------------------------------------------------------------
 382
 383 dnl Set of available languages
 384 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 385 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 386
 387 GETTEXT_PACKAGE=$PACKAGE
 388 AC_SUBST(GETTEXT_PACKAGE)
 389 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${GETTEXT_PACKAGE}"],[Name of gettext file])
 390 AM_GLIB_GNU_GETTEXT
 391 AM_GLIB_DEFINE_LOCALEDIR(GQ_LOCALEDIR)
 392
 393 AC_SUBST(CFLAGS)
 394 AC_SUBST(CXXFLAGS)
 395 AC_SUBST(CPPFLAGS)
 396 AC_SUBST(LDFLAGS)
 397
 398
 399 #  Libchamplain support - used for GPS map facility - experimental
 400 # ----------------------------------------------------------------------
 401
 402 AC_ARG_ENABLE([gps],
 403   AC_HELP_STRING([--enable-gps], [enable GPS map support - experimental]),
 404     [libgps=$enableval], [libgps=auto])
 405
 406 if test "x${libgps}" = "xyes"; then
 407   PKG_CHECK_MODULES(LIBCHAMPLAIN, [champlain-0.12 >= 0.12],
 408     [
 409       HAVE_LIBCHAMPLAIN=yes
 410       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [define to enable use of GPS maps])
 411     ],
 412     [
 413       HAVE_LIBCHAMPLAIN=no
 414       AC_MSG_WARN([$LIBCHAMPLAIN_PKG_ERRORS])
 415     ])
 416 else
 417   HAVE_LIBCHAMPLAIN=disabled
 418 fi
 419
 420 if test "x${libgps}" = "xyes"; then
 421   PKG_CHECK_MODULES(LIBCHAMPLAIN_GTK, [champlain-gtk-0.12 >= 0.12],
 422     [
 423       HAVE_LIBCHAMPLAIN_GTK=yes
 424       AC_DEFINE(HAVE_LIBCHAMPLAIN_GTK, 1, [define to enable use of GPS maps])
 425     ],
 426     [
 427       HAVE_LIBCHAMPLAIN_GTK=no
 428       AC_MSG_WARN([$LIBCHAMPLAIN_GTK_PKG_ERRORS])
 429     ])
 430 else
 431   HAVE_LIBCHAMPLAIN_GTK=disabled
 432 fi
 433
 434 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN_GTK, [test "x$HAVE_LIBCHAMPLAIN_GTK" = xyes])
 435 AC_SUBST(LIBCHAMPLAIN_GTK_CFLAGS)
 436 AC_SUBST(LIBCHAMPLAIN_GTK_LIBS)
 437
 438 AH_TOP([
 439 /** \file
 440  * \short autogenerated definition by autoheader.
 441  * \author Bruclik
 442  */
 443
 444 /*
 445  *  This file is a part of Geeqie project (http://geeqie.sourceforge.net/).
 446  *  Copyright (C) 2008 - 2012 The Geeqie Team
 447  *
 448  *  This program is free software; you can redistribute it and/or modify
 449  *  it under the terms of the GNU General Public License as published by
 450  *  the Free Software Foundation; either version 2 of the License, or
 451  *  (at your option) any later version.
 452  *
 453  *  This program is distributed in the hope that it will be useful,
 454  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 455  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 456  *  GNU General Public License for more details.
 457  */
 458
 459 #ifndef _INCLUDE_CONFIG_H
 460 #define _INCLUDE_CONFIG_H
 461 ])
 462
 463 AH_BOTTOM([#endif])
 464
 465 dnl Write the output
 466 dnl
 467
 468 AC_CONFIG_FILES([
 469     Makefile
 470     src/Makefile
 471     src/icons/Makefile
 472     src/icons/svg/Makefile
 473     po/Makefile.in
 474     doc/Makefile
 475     plugins/Makefile
 476     plugins/symlink/Makefile
 477     plugins/rotate/Makefile
 478     plugins/ufraw/Makefile
 479     plugins/import/Makefile
 480     geeqie.spec
 481 ])
 482
 483 AC_OUTPUT
 484 dnl Print the results
 485 dnl
 486
 487 cat > config.report << END
 488
 489      Config results:
 490     -=-=-=-=-=-=-=-=-
 491
 492 Package:
 493   Name:          $PACKAGE_NAME
 494   Version:       $PACKAGE_VERSION
 495   Patch version: $GQ_PATCH_VERSION
 496   Date:          $GQ_PATCH_DATE
 497
 498 Architecture:
 499   UNIX:          $os_unix
 500   Win32:         $platform_win32 (native: $os_win32)
 501
 502 Flags:
 503   Geeqie:        $GQ_CFLAGS
 504   DEFS:          $DEFS
 505   CPPFLAGS:      $__CPPFLAGS
 506   CFLAGS:        $CFLAGS
 507   CXXFLAGS:      $CXXFLAGS
 508   Gtk:           $GTK_CFLAGS
 509   Glib:          $GLIB_CFLAGS
 510   Thread:        $GTHREAD_LIBS
 511   Others:        $JPEG_LIBS $TIFF_LIBS $LCMS_LIBS $EXIV2_LIBS $LIBCHAMPLAIN_LIBS $LIBCHAMPLAIN_GTK_LIBS
 512
 513 Localization:
 514   NLS support:   $USE_NLS
 515   LINGUAS:       $LINGUAS
 516
 517 Settings:
 518   Developer:     $__IS_DEVELOPER
 519   Debug flags:   $__IS_DEBUG_FLAGS
 520   Debug log:     $__IS_DEBUG_LOG
 521   Deprecated:    $__IS_DEPRECATED
 522
 523 Support:
 524   LCMS:          $HAVE_LCMS
 525   Exiv2:         $HAVE_EXIV2
 526   Lirc:          $HAVE_LIRC
 527   Libchamplain:         $HAVE_LIBCHAMPLAIN
 528   Libchamplain-gtk:     $HAVE_LIBCHAMPLAIN_GTK
 529
 530 Documentation:
 531   Doxygen:       $DOXYGEN
 532   Formats:       $doxy_formats_report
 533   doc-tool:      $GNOME_DOC_TOOL
 534
 535 END
 536
 537 cat config.report
 538 cat <<EOF
 539
 540   Now you can type "make" to build Geeqie
 541   (or you take blue pill and the story ends :)
 542
 543 EOF
 544