configure.in

   1 dnl Process this file with autoconf to produce a configure script.  -*- Autoconf
   2  -*-
   3
   4 dnl This file is a part of Geeqie project (http://www.geeqie.org/).
   5 dnl Copyright (C) 2008 - 2016 The Geeqie Team
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16
  17 AC_PREREQ(2.57)
  18 AC_INIT([geeqie], m4_esyscmd_s(git rev-parse --quiet --verify --short master), [geeqie-devel@lists.sourceforge.net], [], [http://www.geeqie.org/])
  19
  20 # Check for rightly dirs
  21 AC_CONFIG_SRCDIR([src/main.c])
  22
  23 AC_CONFIG_AUX_DIR(auxdir)
  24 # Require Automake 1.14 for %reldir% support
  25 AM_INIT_AUTOMAKE([1.14.1 subdir-objects])
  26
  27 AC_CONFIG_HEADER([config.h])
  28
  29 # Only for developers
  30 AM_MAINTAINER_MODE
  31
  32 AC_ARG_ENABLE(developer, [
  33 Development options:
  34 AC_HELP_STRING([--enable-developer], [turn on developers mode [default=no]])],
  35 [
  36   __IS_DEVELOPER=yes
  37 ],
  38 [
  39 if test "x${enable_developer}" != "xyes"
  40 then
  41   __IS_DEVELOPER=no
  42 else
  43   __IS_DEVELOPER=yes
  44 fi
  45 ])
  46
  47 DX_HTML_FEATURE(ON)
  48 DX_CHM_FEATURE(OFF)
  49 DX_CHI_FEATURE(OFF)
  50 DX_MAN_FEATURE(OFF)
  51 DX_RTF_FEATURE(OFF)
  52 DX_XML_FEATURE(OFF)
  53 DX_PDF_FEATURE(OFF)
  54 DX_PS_FEATURE(OFF)
  55
  56 DX_INIT_DOXYGEN($PACKAGE_NAME, doxygen.conf, doc/doxygen)
  57
  58 #  Debug support
  59 # ----------------------------------------------------------------------
  60
  61 dnl Debugging option
  62 dnl FIXME: official release convert default to 'no'
  63 dnl
  64
  65 AC_ARG_ENABLE([debug-flags], [
  66 Development options:
  67 AC_HELP_STRING([--enable-debug-flags], [use compiler flags for debugging [default=no]])], [],
  68 [
  69 if test "x${enable_developer}" != "xyes"
  70 then
  71   enable_debug_flags="no"
  72 else
  73   enable_debug_flags="yes"
  74 fi
  75 ])
  76
  77 AC_ARG_ENABLE([debug-log], [
  78 Development options:
  79 AC_HELP_STRING([--enable-debug-log], [enable debugging messages [default=yes]])], [], [enable_debug_log="yes"])
  80
  81 if test "x${enable_debug_flags}" != "xno"
  82 then
  83   if test "x${enable_developer}" = "xyes"
  84   then
  85     CXXFLAGS="${CXXFLAGS} -Wall"
  86     CFLAGS="${CFLAGS} -Wstrict-prototypes -Wall"
  87   fi
  88   __COMMONFLAGS="-g -O0 -Wextra -Wunused-value -Wunused-variable -Wunused-function -Wunused-label -Wcomment -Wmissing-braces -Wparentheses -Wreturn-type -Wswitch -Wstrict-aliasing -Wno-unused-parameter -Wformat -Wformat-security -DGQ_DEBUG_PATH_UTF8=1"
  89   CXXFLAGS="${CXXFLAGS} ${__COMMONFLAGS}"
  90   CFLAGS="${CFLAGS} ${__COMMONFLAGS} -Wimplicit-int -Werror-implicit-function-declaration"
  91   __IS_DEBUG_FLAGS=yes
  92 else
  93   __IS_DEBUG_FLAGS=no
  94 fi
  95
  96 if test "x${enable_debug_log}" != "xno"
  97 then
  98   AC_DEFINE(DEBUG,1,[Defined if Geeqie is compiled with debugging messages support])
  99   __IS_DEBUG_LOG=yes
 100 else
 101   __IS_DEBUG_LOG=no
 102 fi
 103
 104 AM_CONDITIONAL(DEBUG, test x$enable_debug_flags = xyes)
 105
 106 AC_ARG_ENABLE(deprecated, [
 107 AC_HELP_STRING([--enable-deprecated], [turn off checking of deprecated functions [default=yes]])], [],
 108 [
 109 if test "x${enable_developer}" != "xyes"
 110 then
 111   enable_deprecated="no"
 112 else
 113   enable_deprecated="yes"
 114 fi
 115 ])
 116
 117 if test "x${enable_deprecated}" != "xno"
 118 then
 119   CXXFLAGS="${CXXFLAGS} -DGTK_DISABLE_DEPRECATED=1 -DGDK_DISABLE_DEPRECATED=1 -DGDK_PIXBUF_DISABLE_DEPRECATED=1 -DG_DISABLE_DEPRECATED=1"
 120   CFLAGS="${CFLAGS} -DGTK_DISABLE_DEPRECATED=1 -DGDK_DISABLE_DEPRECATED=1 -DGDK_PIXBUF_DISABLE_DEPRECATED=1 -DG_DISABLE_DEPRECATED=1"
 121   __IS_DEPRECATED=yes
 122 else
 123   __IS_DEPRECATED=no
 124 fi
 125
 126
 127 AC_ISC_POSIX
 128 AC_PROG_CC
 129 AC_PROG_CXX
 130 AC_STDC_HEADERS
 131 AC_ARG_PROGRAM
 132 AC_SYS_LARGEFILE
 133 IT_PROG_INTLTOOL([0.35.0])
 134
 135
 136 dnl checks for functions
 137 AC_CHECK_FUNCS(strverscmp access fsync fflush)
 138
 139
 140 # Check target architecture
 141
 142 # Check for Win32
 143 AC_MSG_CHECKING([for some Win32 platform])
 144 case "$target_os" in
 145   mingw* | cygwin*)
 146     platform_win32=yes
 147     AC_DEFINE(PLATFORM_WIN32, 1, [Build on win32 OS])
 148     ;;
 149   *)
 150     platform_win32=no
 151     ;;
 152 esac
 153 AC_MSG_RESULT([$platform_win32])
 154 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 155
 156 AC_MSG_CHECKING([for native Win32])
 157 case "$target_os" in
 158   mingw*)
 159     os_win32=yes
 160     AC_DEFINE(OS_WIN32, 1, [Build on native win32 OS])
 161     os_unix=no
 162     PATHSEP=';'
 163     ;;
 164   *)
 165     os_win32=no
 166     os_unix=yes
 167     PATHSEP=':'
 168     ;;
 169 esac
 170 AC_MSG_RESULT([$os_win32])
 171 AC_SUBST(PATHSEP)
 172 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 173 AM_CONDITIONAL(OS_UNIX, test "$os_unix" = "yes")
 174
 175 if test "$os_win32" = "yes"; then
 176   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 177   AC_CHECK_TOOL(WINDRES, windres, :)
 178 else
 179   WINDRES=":"
 180 fi
 181
 182 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 183 AM_CONDITIONAL(HAVE_WINDRES, test "x$WINDRES" != "x:")
 184 AC_SUBST(WINDRES)
 185
 186 dnl reasonable guesses for where stuff is installed
 187 if test "x$prefix" = "xNONE"; then
 188   prefix="/usr/local"
 189 else
 190   prefix=$prefix
 191 fi
 192
 193 AM_PATH_GLIB_2_0(2.24.0,,AC_MSG_ERROR(GLIB >= 2.24.0 not installed.))
 194 AC_ARG_ENABLE([gtk3], AC_HELP_STRING([--disable-gtk3], [use gtk2 instead of gtk3]),[gtk3="${enableval}"], [gtk3=m4_ifdef([AM_PATH_GTK_3_0], [auto], [no])])
 195
 196 if test x$gtk3 == xyes; then
 197     AC_MSG_WARN("Gtk3 enabled")
 198     m4_ifdef([AM_PATH_GTK_3_0], [AM_PATH_GTK_3_0(3.0.0,,AC_MSG_ERROR(GTK+ >= 3.0.0 not installed.))])
 199 else
 200     if test x$gtk3 != xno; then
 201        AC_MSG_WARN("Gtk3 is preferred...")
 202        m4_ifdef([AM_PATH_GTK_3_0], [AM_PATH_GTK_3_0(3.0.0,,[gtk3=no])])
 203     fi
 204 fi
 205
 206 if test x$gtk3 == xno; then
 207     m4_ifdef([AM_PATH_GTK_2_0], [AM_PATH_GTK_2_0(2.20.0,,AC_MSG_ERROR(GTK+ >= 2.20.0 not installed.))])
 208     true
 209 fi
 210
 211 threads="auto"
 212 AC_ARG_ENABLE([threads],
 213   AC_HELP_STRING([--disable-threads], [disable thread support]), [threads="${enableval}"])
 214
 215 have_gthread="no"
 216 if test "x${threads}" != "xno" ; then
 217   PKG_CHECK_MODULES(GTHREAD, [gthread-2.0], have_gthread="yes", [AC_MSG_WARN("No thread support in glib")])
 218 fi
 219
 220 if test "x$have_gthread" != "xno"; then
 221         AC_DEFINE(HAVE_GTHREAD, 1, Define if you have gthread library)
 222         GLIB_CFLAGS="$GTHREAD_CFLAGS"
 223         GLIB_LIBS="$GTHREAD_LIBS"
 224 fi
 225
 226
 227 AC_PATH_PROGS(GDK_PIXBUF_CSOURCE, "gdk-pixbuf-csource")
 228 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
 229
 230 AC_ARG_WITH(readmedir, [  --with-readmedir=DIR    install path for readme files],
 231             readmedir=$withval, readmedir="$prefix/share/doc/geeqie-$VERSION")
 232 AC_ARG_WITH(htmldir, [  --with-htmldir=DIR      install path for html files],
 233             htmldir=$withval, htmldir="$readmedir/html")
 234
 235 AC_DEFINE_UNQUOTED(GQ_HELPDIR, "$readmedir", [Location of documentation files])
 236 AC_DEFINE_UNQUOTED(GQ_HTMLDIR, "$htmldir", [Location of html documentation])
 237
 238 AC_PATH_PROG(GNOME_DOC_TOOL, gnome-doc-tool)
 239
 240 AC_SUBST(readmedir)
 241 AC_SUBST(htmldir)
 242
 243 eval "eval appdir=${datadir}/${PACKAGE}"
 244 AC_DEFINE_UNQUOTED([GQ_APP_DIR], "$appdir", [Location of application data])
 245 AC_SUBST(appdir)
 246
 247 eval "eval gq_bindir=${prefix}/lib/${PACKAGE}"
 248 AC_DEFINE_UNQUOTED([GQ_BIN_DIR], "$gq_bindir", [Location of helper scripts and executables])
 249 AC_SUBST(gq_bindir)
 250
 251 #  LIRC support
 252 # ----------------------------------------------------------------------
 253
 254 dnl Check for LIRC client support
 255 AC_MSG_CHECKING(if LIRC support is enabled)
 256 lirc=no
 257 AC_ARG_ENABLE([lirc],
 258   AC_HELP_STRING([--disable-lirc], [disable lirc support (auto)]),
 259 [
 260 if test "x${enableval}" = "xyes" -a "x$GCC" = "xyes"; then
 261   AC_MSG_RESULT(yes)
 262   lirc=yes
 263 else
 264   AC_MSG_RESULT(no)
 265   lirc=no
 266 fi], AC_MSG_RESULT(no))
 267
 268
 269 AC_ARG_WITH(lirc-prefix,
 270 [  --with-lirc-prefix=PATH Prefix where LIRC is installed],
 271 [
 272 for dir in `echo "$withval" | tr : ' '`; do
 273   if test -d $dir/lib; then CXXFLAGS="$CXXFLAGS -L$dir/lib"; fi
 274   if test -d $dir/include; then CXXFLAGS="$CXXFLAGS -I$dir/include"; fi
 275   done
 276 ])
 277
 278 HAVE_LIRC=no
 279 if test "x${lirc}" != "xno" ; then
 280   AC_CHECK_HEADER(lirc/lirc_client.h,
 281     [AC_CHECK_LIB(lirc_client,lirc_init,[HAVE_LIRC=yes;LIBS=-llirc_client $LIBS;AC_DEFINE([HAVE_LIRC],[],[Define to 1 if LIRC must be used])],,)],)
 282 fi
 283 AM_CONDITIONAL(HAVE_LIRC, [test "x$HAVE_LIRC" = xyes])
 284
 285
 286 #  LCMS support
 287 # ----------------------------------------------------------------------
 288
 289 AC_ARG_ENABLE([lcms],
 290   AC_HELP_STRING([--disable-lcms], [disable lcms support]),
 291     [liblcms=$enableval], [liblcms=auto])
 292
 293 if test "x${liblcms}" != "xno"; then
 294   PKG_CHECK_MODULES(LCMS, [lcms2 >= 2.0],
 295     [
 296       HAVE_LCMS=yes
 297       AC_DEFINE(HAVE_LCMS, 1, [define to enable use of color profiles with lcms])
 298       AC_DEFINE(HAVE_LCMS2, 1, [lcms2 is used])
 299     ],
 300     [
 301     PKG_CHECK_MODULES(LCMS, [lcms >= 1.14],
 302       [
 303         HAVE_LCMS=yes
 304         AC_DEFINE(HAVE_LCMS, 1, [define to enable use of color profiles with lcms])
 305       ],
 306       [
 307         HAVE_LCMS=no
 308         AC_MSG_WARN([$LCMS_PKG_ERRORS])
 309       ])
 310     ])
 311 else
 312   HAVE_LCMS=disabled
 313 fi
 314
 315 AM_CONDITIONAL(HAVE_LCMS, [test "x$HAVE_LCMS" = xyes])
 316 AC_SUBST(LCMS_CFLAGS)
 317 AC_SUBST(LCMS_LIBS)
 318
 319 #  libjpeg support
 320 # ----------------------------------------------------------------------
 321
 322 AC_ARG_ENABLE([jpeg],
 323   AC_HELP_STRING([--disable-jpeg], [disable direct jpeg support]),
 324     [libjpeg=$enableval], [libjpeg=auto])
 325
 326 if test "x${libjpeg}" != "xno"; then
 327   AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 328       HAVE_JPEG=yes
 329       JPEG_LIBS=-ljpeg
 330       AC_DEFINE(HAVE_JPEG, 1, [define to enable use of custom jpeg loader]),
 331       HAVE_JPEG=no)
 332 else
 333   HAVE_JPEG=disabled
 334 fi
 335
 336 AM_CONDITIONAL(HAVE_JPEG, [test "x$HAVE_JPEG" = xyes])
 337 AC_SUBST(JPEG_CFLAGS)
 338 AC_SUBST(JPEG_LIBS)
 339
 340
 341 #  libtiff support
 342 # ----------------------------------------------------------------------
 343
 344 AC_ARG_ENABLE([tiff],
 345   AC_HELP_STRING([--disable-tiff], [disable direct tiff support]),
 346     [libtiff=$enableval], [libtiff=auto])
 347
 348 if test "x${libtiff}" != "xno"; then
 349   AC_CHECK_LIB(tiff, TIFFClientOpen,
 350       HAVE_TIFF=yes
 351       TIFF_LIBS=-ltiff
 352       AC_DEFINE(HAVE_TIFF, 1, [define to enable use of custom tiff loader]),
 353       HAVE_TIFF=no)
 354 else
 355   HAVE_TIFF=disabled
 356 fi
 357
 358 AM_CONDITIONAL(HAVE_TIFF, [test "x$HAVE_TIFF" = xyes])
 359 AC_SUBST(TIFF_CFLAGS)
 360 AC_SUBST(TIFF_LIBS)
 361
 362
 363 #  Exiv2 support
 364 # ----------------------------------------------------------------------
 365
 366 AC_ARG_ENABLE([exiv2],
 367   AC_HELP_STRING([--disable-exiv2], [disable exiv2 support]),
 368     [libexiv2=$enableval], [libexiv2=auto])
 369
 370 if test "x${libexiv2}" != "xno"; then
 371   PKG_CHECK_MODULES(EXIV2, [exiv2 >= 0.11],
 372     [
 373       HAVE_EXIV2=yes
 374       AC_DEFINE(HAVE_EXIV2, 1, [define to enable exiv2 support])
 375     ],
 376     [
 377       HAVE_EXIV2=no
 378       AC_MSG_WARN([$EXIV2_PKG_ERRORS])
 379     ])
 380 else
 381   HAVE_EXIV2=disabled
 382 fi
 383
 384 AM_CONDITIONAL(HAVE_EXIV2, [test "x$HAVE_EXIV2" = xyes])
 385 AC_SUBST(EXIV2_CFLAGS)
 386 AC_SUBST(EXIV2_LIBS)
 387
 388
 389 #  Gettext support
 390 # ----------------------------------------------------------------------
 391
 392 dnl Set of available languages
 393 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 394 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 395
 396 GETTEXT_PACKAGE=$PACKAGE
 397 AC_SUBST(GETTEXT_PACKAGE)
 398 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${GETTEXT_PACKAGE}"],[Name of gettext file])
 399 AM_GLIB_GNU_GETTEXT
 400 AM_GLIB_DEFINE_LOCALEDIR(GQ_LOCALEDIR)
 401
 402 AC_SUBST(CFLAGS)
 403 AC_SUBST(CXXFLAGS)
 404 AC_SUBST(CPPFLAGS)
 405 AC_SUBST(LDFLAGS)
 406
 407
 408 #  clutter and champlain support
 409 # ----------------------------------------------------------------------
 410
 411 AC_ARG_ENABLE([map],
 412   AC_HELP_STRING([--enable-map], [enable map support]),
 413     [libgps=$enableval], [libgps=no])
 414
 415 AC_ARG_ENABLE([gpu-accel],
 416   AC_HELP_STRING([--enable-gpu-accel], [enable GPU acceleration support - experimental]),
 417     [libclutter=$enableval], [libclutter=auto])
 418
 419 if test "x${libclutter}" = "xyes" -o "x${libgps}" = "xyes"; then
 420     if test "x${libclutter}" != "xno" -a "x${gtk3}" != "xno"; then
 421       PKG_CHECK_MODULES(CLUTTER, [clutter-1.0 >= 1.0],
 422         [
 423           PKG_CHECK_MODULES(CLUTTER_GTK, [clutter-gtk-1.0 >= 1.0],
 424             [
 425               HAVE_CLUTTER=yes
 426               AC_DEFINE(HAVE_CLUTTER, 1, [define to enable use of clutter library])
 427             ],
 428             [
 429               HAVE_CLUTTER=no
 430               AC_MSG_WARN([$CLUTTER_GTK_PKG_ERRORS])
 431             ])
 432         ],
 433         [
 434           HAVE_CLUTTER=no
 435           AC_MSG_WARN([$CLUTTER_PKG_ERRORS])
 436         ])
 437     else
 438       HAVE_CLUTTER=disabled
 439     fi
 440 else
 441   HAVE_CLUTTER=disabled
 442 fi
 443
 444 AC_SUBST(CLUTTER_CFLAGS)
 445 AC_SUBST(CLUTTER_LIBS)
 446 AC_SUBST(CLUTTER_GTK_CFLAGS)
 447 AC_SUBST(CLUTTER_GTK_LIBS)
 448
 449
 450 #  Libchamplain support - used for map facility
 451 # ----------------------------------------------------------------------
 452
 453 if test "x${libgps}" = "xyes" -a "x${HAVE_CLUTTER}" = "xyes"; then
 454     if test "x${gtk3}" != "xno"; then
 455       PKG_CHECK_MODULES(LIBCHAMPLAIN, [champlain-0.12 >= 0.12],
 456         [
 457           HAVE_LIBCHAMPLAIN=yes
 458           AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [define to enable use of maps])
 459         ],
 460         [
 461           HAVE_LIBCHAMPLAIN=no
 462           AC_MSG_WARN([$LIBCHAMPLAIN_PKG_ERRORS])
 463         ])
 464     else
 465       HAVE_LIBCHAMPLAIN=disabled
 466     fi
 467 else
 468   HAVE_LIBCHAMPLAIN=disabled
 469 fi
 470
 471 if test "x${libgps}" = "xyes" -a "x${HAVE_LIBCHAMPLAIN}" = "xyes" ; then
 472   PKG_CHECK_MODULES(LIBCHAMPLAIN_GTK, [champlain-gtk-0.12 >= 0.12],
 473     [
 474       HAVE_LIBCHAMPLAIN_GTK=yes
 475       AC_DEFINE(HAVE_LIBCHAMPLAIN_GTK, 1, [define to enable use of maps])
 476     ],
 477     [
 478       HAVE_LIBCHAMPLAIN_GTK=no
 479       AC_MSG_WARN([$LIBCHAMPLAIN_GTK_PKG_ERRORS])
 480     ])
 481 else
 482   HAVE_LIBCHAMPLAIN_GTK=disabled
 483 fi
 484
 485 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN_GTK, [test "x$HAVE_LIBCHAMPLAIN_GTK" = xyes])
 486 AC_SUBST(LIBCHAMPLAIN_GTK_CFLAGS)
 487 AC_SUBST(LIBCHAMPLAIN_GTK_LIBS)
 488
 489 #  Lua support
 490 # ----------------------------------------------------------------------
 491
 492 AC_ARG_ENABLE([lua],
 493   AC_HELP_STRING([--disable-lua], [disable lua support]),
 494     [liblua=$enableval], [liblua=auto])
 495
 496 if test "x${liblua}" != "xno"; then
 497   PKG_CHECK_MODULES(LUA, lua5.1 >= 5.1,
 498     [
 499       HAVE_LUA=yes
 500       AC_DEFINE(HAVE_LUA, 1, [define to enable lua support])
 501     ],
 502     [
 503       HAVE_LUA=no
 504       AC_MSG_WARN([$LUA_PKG_ERRORS])
 505     ])
 506 else
 507   HAVE_LUA=disabled
 508 fi
 509
 510 AM_CONDITIONAL(HAVE_LUA, [test "x$HAVE_LUA" = xyes])
 511 AC_SUBST(LUA_CFLAGS)
 512 AC_SUBST(LUA_LIBS)
 513
 514 # ----------------------------------------------------------------------
 515
 516 AH_TOP([
 517 /** \file
 518  * \short autogenerated definition by autoheader.
 519  * \author Bruclik
 520  */
 521
 522 /*
 523  *  This file is a part of Geeqie project (http://www.geeqie.org/).
 524  *  Copyright (C) 2008 - 2016 The Geeqie Team
 525  *
 526  *  This program is free software; you can redistribute it and/or modify
 527  *  it under the terms of the GNU General Public License as published by
 528  *  the Free Software Foundation; either version 2 of the License, or
 529  *  (at your option) any later version.
 530  *
 531  *  This program is distributed in the hope that it will be useful,
 532  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 533  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 534  *  GNU General Public License for more details.
 535  */
 536
 537 #ifndef _INCLUDE_CONFIG_H
 538 #define _INCLUDE_CONFIG_H
 539 ])
 540
 541 AH_BOTTOM([#endif])
 542
 543 dnl Write the output
 544 dnl
 545
 546 AC_CONFIG_FILES([
 547     Makefile
 548     src/Makefile
 549     src/icons/Makefile
 550     src/icons/svg/Makefile
 551     po/Makefile.in
 552     doc/Makefile
 553     plugins/Makefile
 554     plugins/symlink/Makefile
 555     plugins/rotate/Makefile
 556     plugins/ufraw/Makefile
 557     plugins/import/Makefile
 558     geeqie.spec
 559 ])
 560
 561 AC_OUTPUT
 562 dnl Print the results
 563 dnl
 564
 565 cat > config.report << END
 566
 567      Config results:
 568     -=-=-=-=-=-=-=-=-
 569
 570 Package:
 571   Name:          $PACKAGE_NAME
 572   Version:       $PACKAGE_VERSION
 573
 574 Architecture:
 575   UNIX:          $os_unix
 576   Win32:         $platform_win32 (native: $os_win32)
 577
 578 Flags:
 579   Geeqie:        $GQ_CFLAGS
 580   DEFS:          $DEFS
 581   CPPFLAGS:      $__CPPFLAGS
 582   CFLAGS:        $CFLAGS
 583   CXXFLAGS:      $CXXFLAGS
 584   Gtk:           $GTK_CFLAGS
 585   Glib:          $GLIB_CFLAGS
 586   Thread:        $GTHREAD_LIBS
 587   Others:        $JPEG_LIBS $TIFF_LIBS $LCMS_LIBS $EXIV2_LIBS $CLUTTER_LIBS $CLUTTER_GTK_LIBS $LIBCHAMPLAIN_LIBS $LIBCHAMPLAIN_GTK_LIBS $LUA_LIBS
 588
 589 Localization:
 590   NLS support:   $USE_NLS
 591   LINGUAS:       $LINGUAS
 592
 593 Settings:
 594   Developer:     $__IS_DEVELOPER
 595   Debug flags:   $__IS_DEBUG_FLAGS
 596   Debug log:     $__IS_DEBUG_LOG
 597   Deprecated:    $__IS_DEPRECATED
 598
 599 Support:
 600   LCMS:          $HAVE_LCMS
 601   Exiv2:         $HAVE_EXIV2
 602   Lirc:          $HAVE_LIRC
 603   Clutter:       $HAVE_CLUTTER
 604   Libchamplain:         $HAVE_LIBCHAMPLAIN
 605   Libchamplain-gtk:     $HAVE_LIBCHAMPLAIN_GTK
 606   Lua:           $HAVE_LUA
 607
 608 Documentation:
 609   Doxygen:       $DX_DOXYGEN
 610   doc-tool:      $GNOME_DOC_TOOL
 611
 612 END
 613
 614 cat config.report
 615 cat <<EOF
 616
 617   Now you can type "make" to build Geeqie
 618   (or you take blue pill and the story ends :)
 619
 620 EOF
 621