meson.build

   1 # This file is a part of Geeqie project (https://www.geeqie.org/).
   2 # Copyright (C) 2008 - 2022 The Geeqie Team
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13
  14 # Meson default directories used in this project:
  15 # prefix - /usr/local
  16 # bindir - bin
  17 # datadir - share
  18
  19 # Meson core options:
  20 # buildtype
  21 # debug
  22
  23 # Project expanded default directories:
  24 # prefix        /usr/local/
  25 # bindir        /usr/local/bin                          geeqie executable
  26 # gq_bindir     /usr/local/lib/geeqie               *   plugins scripts
  27 # datadir       /usr/local/share/
  28 #               /usr/local/share/applications           geeqie.desktop
  29 # [gq_]appdir   /usr/local/share/geeqie/            *   template.desktop
  30 # desktopdir    /usr/local/share/geeqie/applications    plugin desktop files
  31 # appdatadir    /usr/local/share/metainfo               org.geeqie.Geeqie.appdata.xml
  32 # icondir       /usr/local/share/pixmaps                geeqie.png icon
  33 # [gq_]helpdir  /usr/local/share/doc/geeqie         *   readme files etc.
  34 # [gq_]htmldir  /usr/local/share/doc/geeqie/html    *   help files
  35 # gq_localedir  /usr/locale/share/locale
  36 # mandir1       /usr/local/share/man/man1               man page
  37 # podir         project_root/po
  38
  39 # * See meson_options.txt file
  40
  41 project(
  42     'geeqie',
  43     'c',
  44     'cpp',
  45     version : run_command('./version.sh', check : true).stdout().strip(),
  46     license : ['GPL-2.0-or-later'],
  47     meson_version : '>=0.53.0',
  48     default_options : ['warning_level=3', 'buildtype=debugoptimized']
  49 )
  50
  51 # To inhibit warnings from the generated files icons_inline.h and ui_icons.h
  52 add_global_arguments('-Wno-overlength-strings', language : 'c')
  53
  54 # Project requirements
  55 project_sources = []
  56 gnome = import('gnome')
  57 thread_dep = dependency('threads')
  58 cc = meson.get_compiler('c')
  59 i18n = import('i18n')
  60 configuration_inc = include_directories('.')
  61
  62 # External programs
  63 gdk_pixbuf_csource = find_program('gdk-pixbuf-csource', required : true)
  64 glib_genmarshal = find_program('glib-genmarshal', required : true)
  65 gnome_doc_tool = find_program('yelp-build', required : false)
  66 if gnome_doc_tool.found()
  67     summary({'help' : ['Help files created:', true]}, section : 'Documentation', bool_yn : true)
  68 else
  69     summary({'help' : ['yelp-build not found - Help files created:', false]}, section : 'Documentation', bool_yn : true)
  70 endif
  71
  72 debug = get_option('debug')
  73
  74 # Note that main.c sets prefix to the directory above where the executable is run from.
  75 # This is to allow AppImages to be used
  76
  77 # These gq_* variables are paths relative to /prefix/,
  78 # and are also used in defines in the source as GQ_*
  79 if get_option('gq_appdir') == ''
  80     gq_appdir = join_paths(get_option('datadir'), 'geeqie')
  81 else
  82     gq_appdir = get_option('gq_appdir')
  83 endif
  84
  85 # This is not the same as Meson bindir
  86 if get_option('gq_bindir') == ''
  87     gq_bindir = 'lib/geeqie'
  88 else
  89     gq_bindir = get_option('gq_bindir')
  90 endif
  91
  92 if get_option('gq_helpdir') == ''
  93     gq_helpdir = join_paths(get_option('datadir'), 'doc/geeqie')
  94 else
  95     gq_helpdir = get_option('gq_helpdir')
  96 endif
  97
  98 if get_option('gq_htmldir') == ''
  99     gq_htmldir = join_paths(get_option('datadir'), 'doc/geeqie/html')
 100 else
 101     gq_htmldir = get_option('gq_htmldir')
 102 endif
 103
 104 if get_option('gq_localedir') == ''
 105     gq_localedir = join_paths(get_option('datadir'), 'locale')
 106 else
 107     gq_localedir = get_option('gq_localedir')
 108 endif
 109
 110
 111 # Set up the absolute directory paths used
 112 prefix = get_option('prefix')
 113 datadir = join_paths(prefix, get_option('datadir'))
 114
 115 # Installation paths are absolute
 116 appdir = join_paths(prefix, gq_appdir)
 117 appdatadir = join_paths(datadir, 'metainfo')
 118 desktopdir = join_paths(datadir, meson.project_name(), 'applications')
 119 helpdir = join_paths(prefix, gq_helpdir)
 120 htmldir = join_paths(prefix, gq_htmldir)
 121 icondir = join_paths(datadir, 'pixmaps')
 122 mandir1 = join_paths(datadir, 'man', 'man1')
 123
 124 podir = join_paths(meson.source_root(), 'po')
 125
 126 summary({'gq_appdir': gq_appdir,
 127         'gq_bindir': gq_helpdir,
 128         'gq_helpdir': gq_helpdir,
 129         'gq_htmldir': gq_htmldir,
 130         'gq_localedir': gq_localedir,
 131         }, section: 'Directories')
 132
 133 # Create the define constants used in the sources. Set via config.h.in
 134 conf_data = configuration_data()
 135 conf_data.set_quoted('VERSION', run_command('./version.sh', check : true).stdout())
 136 conf_data.set('DEBUG', debug)
 137
 138 gtk_dep = dependency('gtk+-3.0', version : '>=3.22', required: true)
 139 glib_dep = dependency('glib-2.0', version : '>=2.52', required: true)
 140
 141 libarchive_dep = []
 142 req_version = '>=3.4.0'
 143 option = get_option('archive')
 144 if not option.disabled()
 145     libarchive_dep = dependency('libarchive', version : req_version, required : get_option('archive'))
 146     if libarchive_dep.found()
 147         conf_data.set('HAVE_ARCHIVE', 1)
 148         summary({'archive' : ['archive files e.g. .zip supported:', true]}, section : 'Configuration', bool_yn : true)
 149     else
 150         summary({'archive' : ['libarchive ' + req_version + ' not found - archive files e.g. .zip supported::', false]}, section : 'Configuration', bool_yn : true)
 151     endif
 152 else
 153     summary({'archive' : ['disabled - archive files e.g. .zip supported:', false]}, section : 'Configuration', bool_yn : true)
 154 endif
 155
 156 lcms_dep = []
 157 req_version = '>=2.0'
 158 option = get_option('cms')
 159 if not option.disabled()
 160     lcms_dep = dependency('lcms2', version : req_version, required : get_option('cms'))
 161     if lcms_dep.found()
 162         conf_data.set('HAVE_LCMS', 1)
 163         conf_data.set('HAVE_LCMS2', 1)
 164         summary({'cms' : ['color management supported:', true]}, section : 'Configuration', bool_yn : true)
 165     else
 166         summary({'cms' : ['lcms2' + req_version + ' not found - color management supported:', false]}, section : 'Configuration', bool_yn : true)
 167     endif
 168 else
 169     summary({'cms' : ['disabled - color management supported:', false]}, section : 'Configuration', bool_yn : true)
 170 endif
 171
 172 ddjvuapi_dep = []
 173 req_version = '>=2.5.27'
 174 option = get_option('djvu')
 175 if not option.disabled()
 176     ddjvuapi_dep = dependency('ddjvuapi', version : req_version, required : get_option('djvu'))
 177     if ddjvuapi_dep.found()
 178         conf_data.set('HAVE_DJVU', 1)
 179         summary({'djvu' : ['djvu files supported:', true]}, section : 'Configuration', bool_yn : true)
 180     else
 181         summary({'djvu' : ['ddjvuapi ' + req_version + ' not found - djvu files supported:', false]}, section : 'Configuration', bool_yn : true)
 182     endif
 183 else
 184     summary({'djvu' : ['disabled - djvu files supported:', false]}, section : 'Configuration', bool_yn : true)
 185 endif
 186
 187 exiv2_dep = []
 188 req_version = '>=0.11'
 189 option = get_option('exiv2')
 190 if not option.disabled()
 191     exiv2_dep = dependency('exiv2', version : req_version, required : get_option('exiv2'))
 192     if exiv2_dep.found()
 193         conf_data.set('HAVE_EXIV2', 1)
 194         summary({'exiv2' : ['image metadata processed by exiv2:', true]}, section : 'Configuration', bool_yn : true)
 195     else
 196         summary({'exiv2' : ['exiv2 ' + req_version + ' not found - image data not processed by exiv2:', false]}, section : 'Configuration', bool_yn : true)
 197     endif
 198 else
 199     summary({'exiv2' : ['disabled - image data processed by exiv2:', false]}, section : 'Configuration', bool_yn : true)
 200 endif
 201
 202 libffmpegthumbnailer_dep = []
 203 req_version = '>=2.1.0'
 204 option = get_option('videothumbnailer')
 205 if not option.disabled()
 206     libffmpegthumbnailer_dep = dependency('libffmpegthumbnailer',
 207         version : req_version,
 208         required : get_option('videothumbnailer'))
 209
 210     if libffmpegthumbnailer_dep.found()
 211         conf_data.set('HAVE_FFMPEGTHUMBNAILER', 1)
 212         summary({'videothumbnailer' : ['thumbnails of video files supported:', true]}, section : 'Configuration', bool_yn : true)
 213
 214         result = cc.has_member('struct video_thumbnailer_struct', 'prefer_embedded_metadata', prefix : '#include <libffmpegthumbnailer/videothumbnailerc.h>')
 215         if result
 216             conf_data.set('HAVE_FFMPEGTHUMBNAILER_METADATA', 1)
 217         endif
 218         summary({'fmpegthumbnailer_metadata' : ['fmpegthumbnailer_metadata found:', result]}, section : 'Thumbnailer', bool_yn : true)
 219
 220         result = cc.has_member('struct image_data_struct', 'image_data_width', prefix : '#include <libffmpegthumbnailer/videothumbnailerc.h>' )
 221         if result
 222             conf_data.set('HAVE_FFMPEGTHUMBNAILER_RGB', 1)
 223         endif
 224         summary({'fmpegthumbnailer_rgb' : ['fmpegthumbnailer_rgb found:', result]}, section : 'Thumbnailer', bool_yn : true)
 225
 226         result = cc.has_function('video_thumbnailer_set_size', dependencies : libffmpegthumbnailer_dep)
 227         if result
 228             conf_data.set('HAVE_FFMPEGTHUMBNAILER_WH', 1)
 229         endif
 230         summary({'fmpegthumbnailer_set_size' : ['fmpegthumbnailer_set_size found:', result]}, section : 'Thumbnailer', bool_yn : true)
 231     else
 232         summary({'videothumbnailer' : ['libvideothumbnailer ' + req_version + ' not found - thumbnails of video files supported', false]}, section : 'Configuration', bool_yn : true)
 233     endif
 234 else
 235     summary({'videothumbnailer' : ['disabled -thumbnails of video files supported', false]}, section : 'Configuration', bool_yn : true)
 236 endif
 237
 238 champlain_dep = []
 239 champlain_gtk_dep = []
 240 clutter_dep = []
 241 clutter_gtk_dep = []
 242 req_version_champlain = '>=0.12'
 243 req_version_champlain_gtk = '>=0.12'
 244 req_version_clutter = '>=1.0'
 245 req_version_clutter_gtk = '>=1.0'
 246 option = get_option('gps-map')
 247 if not option.disabled()
 248     champlain_dep = dependency('champlain-0.12', version : req_version_champlain, required : get_option('gps-map'))
 249     champlain_gtk_dep = dependency('champlain-gtk-0.12', version : req_version_champlain_gtk, required : get_option('gps-map'))
 250     if champlain_dep.found() and champlain_gtk_dep.found()
 251         clutter_dep = dependency('clutter-1.0', version : req_version_clutter, required : get_option('gps-map'))
 252         clutter_gtk_dep = dependency('clutter-gtk-1.0', version : req_version_clutter_gtk, required : get_option('gps-map'))
 253         if clutter_dep.found() and clutter_gtk_dep.found()
 254             conf_data.set('HAVE_CLUTTER', 1)
 255             conf_data.set('HAVE_LIBCHAMPLAIN', 1)
 256             conf_data.set('HAVE_LIBCHAMPLAIN_GTK', 1)
 257             summary({'gps-map' : ['GPS map displayed', true]}, section : 'Configuration', bool_yn : true)
 258         else
 259             if not clutter_dep.found()
 260                 summary({'gps-map-clutter' : ['clutter-1.0 ' + req_version_clutter + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 261             endif
 262             if not clutter_gtk_dep.found()
 263                 summary({'gps-map-clutter-gtk' : ['clutter-gtk-1.0 ' + req_version_clutter_gtk + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 264             endif
 265         endif
 266     else
 267         if not champlain_dep.found()
 268             summary({'gps-map-champlain' : ['champlain-0.12 ' + req_version_champlain + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 269         endif
 270         if not champlain_gtk_dep.found()
 271             summary({'gps-map-champlain-gtk' : ['champlain-gtk-0.12 ' + req_version_champlain_gtk + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 272         endif
 273     endif
 274 else
 275     summary({'gps-map' : ['disabled - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 276 endif
 277
 278 libheif_dep = []
 279 req_version = '>=1.3.2'
 280 option = get_option('heif')
 281 if not option.disabled()
 282     libheif_dep = dependency('libheif', version : req_version, required : get_option('heif'))
 283     if libheif_dep.found()
 284         conf_data.set('HAVE_HEIF', 1)
 285         summary({'heif' : ['heif files supported:', true]}, section : 'Configuration', bool_yn : true)
 286     else
 287         summary({'heif' : ['libheif ' + req_version + ' not found - heif files supported:', false]}, section : 'Configuration', bool_yn : true)
 288     endif
 289 else
 290     summary({'heif' : ['disabled - heif files supported:', false]}, section : 'Configuration', bool_yn : true)
 291 endif
 292
 293 libopenjp2_dep = []
 294 req_version = '>=2.3.0'
 295 option = get_option('j2k')
 296 if not option.disabled()
 297     libopenjp2_dep = dependency('libopenjp2', version : req_version, required : get_option('j2k'))
 298     if libopenjp2_dep.found()
 299         conf_data.set('HAVE_J2K', 1)
 300         summary({'j2k' : ['j2k files supported:', true]}, section : 'Configuration', bool_yn : true)
 301     else
 302         summary({'j2k' : ['libopenjp2 ' + req_version + ' not found - j2k files supported:', false]}, section : 'Configuration', bool_yn : true)
 303     endif
 304 else
 305     summary({'j2k' : ['disabled - j2k files supported:', false]}, section : 'Configuration', bool_yn : true)
 306 endif
 307
 308 libjpeg_dep = []
 309 option = get_option('jpeg')
 310 if not option.disabled()
 311 libjpeg_dep = dependency('libjpeg', required : get_option('jpeg'))
 312     if libjpeg_dep.found()
 313         if cc.has_function('jpeg_destroy_decompress', dependencies : libjpeg_dep)
 314             conf_data.set('HAVE_JPEG', 1)
 315             summary({'jpeg' : ['jpeg files supported:', true]}, section : 'Configuration', bool_yn : true)
 316         else
 317             summary({'jpeg' : ['jpeg_destroy_decompress not found - jpeg files supported:', false]}, section : 'Configuration', bool_yn : true)
 318         endif
 319     else
 320         summary({'jpeg' : ['libjpeg: not found', false]}, section : 'Configuration', bool_yn : true)
 321     endif
 322 else
 323     summary({'jpeg' : ['disabled - jpeg files supported:', false]}, section : 'Configuration', bool_yn : true)
 324 endif
 325
 326 libjxl_dep = []
 327 req_version = '>=0.3.7'
 328 option = get_option('jpegxl')
 329 if not option.disabled()
 330     libjxl_dep = dependency('libjxl', version : req_version, required : get_option('jpegxl'))
 331     if libjxl_dep.found()
 332         conf_data.set('HAVE_JPEGXL', 1)
 333         summary({'jpegxl' : ['jpegxl files supported:', true]}, section : 'Configuration', bool_yn : true)
 334     else
 335         summary({'jpegxl' : ['libjxl ' + req_version + ' not found - jpegxl files supported:', false]}, section : 'Configuration', bool_yn : true)
 336     endif
 337 else
 338     summary({'jpegxl' : ['disabled - jpegxl files supported:', false]}, section : 'Configuration', bool_yn : true)
 339 endif
 340
 341 libraw_dep = []
 342 req_version = '>=0.20'
 343 option = get_option('libraw')
 344 if not option.disabled()
 345     libraw_dep = dependency('libraw', version : req_version, required : get_option('libraw'))
 346     if libraw_dep.found()
 347         conf_data.set('HAVE_RAW', 1)
 348         summary({'libraw' : ['.cr3 files supported:', true]}, section : 'Configuration', bool_yn : true)
 349     else
 350         summary({'libraw' : ['libraw ' + req_version + ' not found - .cr3 files supported:', false]}, section : 'Configuration', bool_yn : true)
 351     endif
 352 else
 353     summary({'libraw' : ['disabled - .cr3 files supported:', false]}, section : 'Configuration', bool_yn : true)
 354 endif
 355
 356 lua_dep = []
 357 req_version = '>=5.3'
 358 option = get_option('lua')
 359 if not option.disabled()
 360     lua_dep = dependency('lua5.3',  version : req_version, required : get_option('lua'))
 361     if lua_dep.found()
 362         conf_data.set('HAVE_LUA', 1)
 363         summary({'lua' : ['lua supported:', true]}, section : 'Configuration', bool_yn : true)
 364     else
 365         summary({'lua' : ['lua5.3 ' + req_version + ' not found - lua supported:', false]}, section : 'Configuration', bool_yn : true)
 366     endif
 367 else
 368     summary({'lua' : ['disabled - lua supported:', false]}, section : 'Configuration', bool_yn : true)
 369 endif
 370
 371 poppler_glib_dep = []
 372 req_version = '>=0.62'
 373 option = get_option('pdf')
 374 if not option.disabled()
 375     poppler_glib_dep = dependency('poppler-glib', version : req_version, required : get_option('pdf'))
 376     if poppler_glib_dep.found()
 377         conf_data.set('HAVE_PDF', 1)
 378         summary({'pdf'  : ['pdf files supported:', true]}, section : 'Configuration', bool_yn : true)
 379     else
 380         summary({'pdf' : ['poppler-glib ' + req_version + ' not found - pdf files supported:', false]}, section : 'Configuration', bool_yn : true)
 381     endif
 382 else
 383     summary({'pdf' : ['disabled - pdf files supported:', false]}, section : 'Configuration', bool_yn : true)
 384 endif
 385
 386 gspell_dep = []
 387 req_version = '>=1.6'
 388 option = get_option('spell')
 389 if not option.disabled()
 390     gspell_dep = dependency('gspell-1', version : req_version, required: get_option('spell'))
 391     if gspell_dep.found()
 392         conf_data.set('HAVE_SPELL', 1)
 393         summary({'spell' : ['spelling checks enabled', true]}, section : 'Configuration', bool_yn : true)
 394     else
 395         summary({'spell' : ['gspell-1 ' + req_version + ' not found - spelling checks not enabled', false]}, section : 'Configuration', bool_yn : true)
 396     endif
 397 else
 398     summary({'spell' : ['disabled - spelling checks not enabled', false]}, section : 'Configuration', bool_yn : true)
 399 endif
 400
 401 tiff_dep = []
 402 option = get_option('tiff')
 403 if not option.disabled()
 404     tiff_dep = cc.find_library('libtiff', required: get_option('tiff'))
 405     if tiff_dep.found()
 406         if cc.has_function('TIFFClientOpen', dependencies : tiff_dep)
 407             conf_data.set('HAVE_TIFF', 1)
 408             summary({'tiff' : ['tiff files supported:', true]}, section : 'Configuration', bool_yn : true)
 409         else
 410             summary({'tiff' : ['TIFFClientOpen not found - tiff files supported:', false]}, section : 'Configuration', bool_yn : true)
 411         endif
 412     else
 413         summary({'tiff' : ['libtiff not found - tiff files supported:', false]}, section : 'Configuration', bool_yn : true)
 414     endif
 415 else
 416     summary({'tiff' : ['disabled - tiff files supported:', false]}, section : 'Configuration', bool_yn : true)
 417 endif
 418
 419 libwebp_dep = []
 420 req_version = '>=0.6.1'
 421 option = get_option('webp')
 422 if not option.disabled()
 423     libwebp_dep = dependency('libwebp', version : req_version, required : get_option('webp'))
 424     if libwebp_dep.found()
 425         conf_data.set('HAVE_WEBP', 1)
 426         summary({'webp' : ['webp files supported:', true]}, section : 'Configuration', bool_yn : true)
 427     else
 428         summary({'webp' : ['libwebp ' + req_version + ' not found - webp files supported:', false]}, section : 'Configuration', bool_yn : true)
 429     endif
 430 else
 431     summary({'webp' : ['disabled - webp files supported:', false]}, section : 'Configuration', bool_yn : true)
 432 endif
 433
 434 # Check for nl_langinfo and _NL_TIME_FIRST_WEEKDAY
 435 code = '''#include <langinfo.h>
 436 #include<stdio.h>
 437 int main (int argc, char ** argv) {
 438     char *c;
 439     c =  nl_langinfo(_NL_TIME_FIRST_WEEKDAY);
 440     return 0;
 441 }'''
 442 if cc.links(code, name : 'nl_langinfo and _NL_TIME_FIRST_WEEKDAY')
 443     conf_data.set('HAVE__NL_TIME_FIRST_WEEKDAY', 1)
 444     summary({'nl_langinfo' : ['first weekday depends on locale:', true]}, section : 'Documentation', bool_yn : true)
 445 else
 446     summary({'nl_langinfo' : ['nl_langinfo not found - first weekday depends on locale:', false, 'first weekday defaults to Monday']}, section : 'Documentation', bool_yn : true)
 447 endif
 448
 449 conf_data.set_quoted('GETTEXT_PACKAGE', meson.project_name())
 450 conf_data.set_quoted('GQ_APPDIR', gq_appdir)
 451 conf_data.set_quoted('GQ_BINDIR', gq_bindir)
 452 conf_data.set_quoted('GQ_HELPDIR', gq_helpdir)
 453 conf_data.set_quoted('GQ_HTMLDIR', gq_htmldir)
 454 conf_data.set_quoted('GQ_LOCALEDIR', gq_localedir)
 455
 456 conf_data.set_quoted('PACKAGE', meson.project_name())
 457 conf_data.set_quoted('PACKAGE_NAME', meson.project_name())
 458 conf_data.set_quoted('PACKAGE_STRING', meson.project_version())
 459 conf_data.set_quoted('PACKAGE_TARNAME', meson.project_name())
 460 conf_data.set_quoted('PACKAGE_VERSION', meson.project_version())
 461 conf_data.set_quoted('VERSION', meson.project_version())
 462
 463 configure_file(input : 'config.h.in',
 464                output : 'config.h',
 465                encoding : 'UTF-8',
 466                configuration : conf_data)
 467
 468 # Process subdirs before the sources
 469 subdir('po')
 470 subdir('plugins')
 471
 472 # Generate the executable
 473 subdir('src')
 474
 475 # Generate the help files
 476 subdir('doc')
 477
 478 # Install other project files
 479 res = run_command(find_program('gen_changelog.sh'), meson.source_root(), meson.build_root(), check : false)
 480
 481 if res.returncode() == 0
 482     install_data(join_paths(meson.build_root(), 'ChangeLog'), join_paths(meson.build_root(), 'ChangeLog.html'), install_dir : helpdir)
 483     summary({'ChangeLog' : ['ChangeLog, ChangeLog.html created:', true]}, section : 'Documentation', bool_yn : true)
 484 else
 485     summary({'ChangeLog' : ['ChangeLog, ChangeLog.html created:', false]}, section : 'Documentation', bool_yn : true)
 486 endif
 487
 488 pandoc = find_program('pandoc', required : false)
 489 if pandoc.found()
 490     run_command(find_program('gen_readme.sh'), meson.source_root(), meson.build_root(), check : false)
 491
 492     install_data('README.md', 'COPYING', 'TODO', 'AUTHORS',
 493                  join_paths(meson.build_root(), 'README.html'),
 494                  install_dir : helpdir)
 495     summary({'README' : ['README.html created:', true]}, section : 'Documentation', bool_yn : true)
 496 else
 497     install_data('README.md', 'COPYING', 'TODO', 'AUTHORS',
 498                  install_dir : helpdir)
 499     summary({'README' : ['pandoc not found - README.html created:', false]}, section : 'Documentation', bool_yn : true)
 500 endif
 501
 502 evince = find_program('evince', required : false)
 503 if evince.found()
 504     summary({'print preview' : ['print preview supported:', true]}, section : 'Documentation', bool_yn : true)
 505 else
 506     summary({'print preview' : ['evince not found - print preview supported:', false]}, section : 'Documentation', bool_yn : true)
 507 endif
 508
 509 install_data('geeqie.png', install_dir : icondir)
 510 install_data('geeqie.1', install_dir : mandir1)
 511
 512 i18n.merge_file(
 513     input : 'geeqie.desktop.in',
 514     output : 'geeqie.desktop',
 515     type : 'desktop',
 516     po_dir : podir,
 517     install : true,
 518     install_dir : join_paths(datadir, 'applications'))
 519
 520 i18n.merge_file(
 521     input : 'org.geeqie.Geeqie.appdata.xml.in',
 522     output : 'org.geeqie.Geeqie.appdata.xml',
 523     type : 'xml',
 524     po_dir : podir,
 525     install : true,
 526     install_dir : appdatadir)
 527
 528 configure_file(input: 'geeqie.spec.in', output: 'geeqie.spec', configuration: conf_data)