meson.build

   1 # This file is a part of Geeqie project (https://www.geeqie.org/).
   2 # Copyright (C) 2008 - 2022 The Geeqie Team
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13
  14 # Meson default directories used in this project:
  15 # prefix - /usr/local
  16 # bindir - bin
  17 # datadir - share
  18
  19 # Meson core options:
  20 # buildtype
  21 # debug
  22
  23 # Project expanded default directories:
  24 # prefix        /usr/local/
  25 # bindir        /usr/local/bin                          geeqie executable
  26 # gq_bindir     /usr/local/lib/geeqie               *   plugins scripts
  27 # datadir       /usr/local/share/
  28 #               /usr/local/share/applications           geeqie.desktop
  29 # [gq_]appdir   /usr/local/share/geeqie/            *   template.desktop
  30 # desktopdir    /usr/local/share/geeqie/applications    plugin desktop files
  31 # appdatadir    /usr/local/share/metainfo               org.geeqie.Geeqie.appdata.xml
  32 # icondir       /usr/local/share/pixmaps                geeqie.png icon
  33 # [gq_]helpdir  /usr/local/share/doc/geeqie         *   readme files etc.
  34 # [gq_]htmldir  /usr/local/share/doc/geeqie/html    *   help files
  35 # gq_localedir  /usr/locale/share/locale
  36 # mandir1       /usr/local/share/man/man1               man page
  37 # podir         project_root/po
  38
  39 # * See meson_options.txt file
  40
  41 project(
  42     'geeqie',
  43     'c',
  44     'cpp',
  45     version : run_command('./version.sh', check : true).stdout().strip(),
  46     license : ['GPL-2.0-or-later'],
  47     meson_version : '>=0.56.2',
  48     default_options : ['cpp_std=c++14', 'warning_level=3', 'buildtype=debugoptimized', 'cpp_link_args=-rdynamic']
  49 )
  50
  51 # To inhibit warnings from the generated files icons_inline.h and ui_icons.h
  52 add_global_arguments('-Wno-overlength-strings', language : 'c')
  53
  54 # To compile originally-C files as C++
  55 add_global_arguments('-Wno-error=deprecated-declarations', language : 'cpp')
  56 add_global_arguments('-Wno-error=sign-compare', language : 'cpp')
  57 add_global_arguments('-Wno-error=return-type', language : 'cpp')
  58 add_global_arguments('-Wno-error=literal-suffix', language : 'cpp')
  59 add_global_arguments('-Wno-error=write-strings', language : 'cpp')
  60
  61 # Project requirements
  62 project_sources = []
  63 gnome = import('gnome')
  64 thread_dep = dependency('threads')
  65 cc = meson.get_compiler('c')
  66 i18n = import('i18n')
  67 fs = import('fs')
  68 configuration_inc = include_directories('.')
  69
  70 # Extended stack trace using backward-app
  71 option = get_option('devel')
  72 if option.enabled()
  73     if cc.has_link_argument('-ldwarf')
  74         add_project_link_arguments('-ldwarf', language: 'cpp')
  75     endif
  76 endif
  77
  78 # External programs
  79 gdk_pixbuf_csource = find_program('gdk-pixbuf-csource', required : true)
  80 glib_compile_resources = find_program('glib-compile-resources', required : true)
  81 glib_genmarshal = find_program('glib-genmarshal', required : true)
  82
  83 option = get_option('git')
  84 if not option.disabled()
  85     running_from_git = find_program('git', required: false).found() and fs.is_dir('.git')
  86 else
  87     running_from_git = false
  88     summary({'git' : ['disabled - ChangeLog, ChangeLog.html, lua-api help file created:', false]}, section : 'Documentation', bool_yn : true)
  89 endif
  90
  91 debug = get_option('debug')
  92
  93 # Note that main.cc sets prefix to the directory above where the executable is run from.
  94 # This is to allow AppImages to be used
  95
  96 # These gq_* variables are paths relative to /prefix/,
  97 # and are also used in defines in the source as GQ_*
  98 if get_option('gq_appdir') == ''
  99     gq_appdir = join_paths(get_option('datadir'), 'geeqie')
 100 else
 101     gq_appdir = get_option('gq_appdir')
 102 endif
 103
 104 # This is not the same as Meson bindir
 105 if get_option('gq_bindir') == ''
 106     gq_bindir = 'lib/geeqie'
 107 else
 108     gq_bindir = get_option('gq_bindir')
 109 endif
 110
 111 if get_option('gq_helpdir') == ''
 112     gq_helpdir = join_paths(get_option('datadir'), 'doc/geeqie')
 113 else
 114     gq_helpdir = get_option('gq_helpdir')
 115 endif
 116
 117 if get_option('gq_htmldir') == ''
 118     gq_htmldir = join_paths(get_option('datadir'), 'doc/geeqie/html')
 119 else
 120     gq_htmldir = get_option('gq_htmldir')
 121 endif
 122
 123 if get_option('gq_localedir') == ''
 124     gq_localedir = join_paths(get_option('datadir'), 'locale')
 125 else
 126     gq_localedir = get_option('gq_localedir')
 127 endif
 128
 129
 130 # Set up the absolute directory paths used
 131 prefix = get_option('prefix')
 132 datadir = join_paths(prefix, get_option('datadir'))
 133
 134 # Installation paths are absolute
 135 appdir = join_paths(prefix, gq_appdir)
 136 appdatadir = join_paths(datadir, 'metainfo')
 137 desktopdir = join_paths(datadir, meson.project_name(), 'applications')
 138 helpdir = join_paths(prefix, gq_helpdir)
 139 htmldir = join_paths(prefix, gq_htmldir)
 140 icondir = join_paths(datadir, 'pixmaps')
 141 mandir1 = join_paths(datadir, 'man', 'man1')
 142
 143 podir = join_paths(meson.project_source_root(), 'po')
 144 scriptsdir = join_paths(meson.project_source_root(), 'scripts')
 145
 146 summary({'gq_appdir': gq_appdir,
 147         'gq_bindir': gq_helpdir,
 148         'gq_helpdir': gq_helpdir,
 149         'gq_htmldir': gq_htmldir,
 150         'gq_localedir': gq_localedir,
 151         }, section: 'Directories')
 152
 153 # Create the define constants used in the sources. Set via config.h.in
 154 conf_data = configuration_data()
 155 conf_data.set_quoted('VERSION', meson.project_version())
 156 conf_data.set('DEBUG', debug)
 157
 158 option = get_option('gtk4')
 159 if option.enabled()
 160     gtk_dep = dependency('gtk4', required: true)
 161     conf_data.set('HAVE_GTK4', 1)
 162 else
 163     gtk_dep = dependency('gtk+-3.0', version : '>=3.24', required: true)
 164 endif
 165 glib_dep = dependency('glib-2.0', version : '>=2.52', required: true)
 166
 167 # Required only when backward-cpp is used
 168 libdw_dep = []
 169 libunwind_dep = []
 170 option = get_option('devel')
 171 if option.enabled()
 172     libdw_dep = dependency('libdw', required : true)
 173     if libdw_dep.found()
 174         libunwind_dep = dependency('libunwind', required : true)
 175         if libunwind_dep.found()
 176             conf_data.set('HAVE_DEVELOPER', 1)
 177             summary({'developer mode' : ['extended stacktrace:', true]}, section : 'Debugging', bool_yn : true)
 178         else
 179             summary({'developer mode' : ['libunwind not found. extended stacktrace:', false]}, section : 'Debugging', bool_yn : true)
 180         endif
 181     else
 182         summary({'developer mode' : ['libdw not found. extended stacktrace:', false]}, section : 'Debugging', bool_yn : true)
 183     endif
 184 else
 185     summary({'developer mode' : ['extended stacktrace:', false]}, section : 'Debugging', bool_yn : true)
 186 endif
 187
 188 # Required only for seg. fault stacktrace and backtrace debugging
 189 option = get_option('execinfo')
 190 if not option.disabled()
 191     result = cc.check_header('execinfo.h')
 192     if result
 193         conf_data.set('HAVE_EXECINFO_H', 1)
 194         summary({'execinfo' : ['stacktrace supported:', true]}, section : 'Debugging', bool_yn : true)
 195     else
 196         summary({'execinfo' : ['stacktrace supported:', false]}, section : 'Debugging', bool_yn : true)
 197     endif
 198 else
 199     summary({'execinfo' : ['stacktrace supported:', false]}, section : 'Debugging', bool_yn : true)
 200 endif
 201
 202 libarchive_dep = []
 203 req_version = '>=3.4.0'
 204 option = get_option('archive')
 205 if not option.disabled()
 206     libarchive_dep = dependency('libarchive', version : req_version, required : get_option('archive'))
 207     if libarchive_dep.found()
 208         conf_data.set('HAVE_ARCHIVE', 1)
 209         summary({'archive' : ['archive files e.g. .zip supported:', true]}, section : 'Configuration', bool_yn : true)
 210     else
 211         summary({'archive' : ['libarchive ' + req_version + ' not found - archive files e.g. .zip supported::', false]}, section : 'Configuration', bool_yn : true)
 212     endif
 213 else
 214     summary({'archive' : ['disabled - archive files e.g. .zip supported:', false]}, section : 'Configuration', bool_yn : true)
 215 endif
 216
 217 lcms_dep = []
 218 req_version = '>=2.0'
 219 option = get_option('cms')
 220 if not option.disabled()
 221     xxd = find_program('xxd', 'xxdi.pl', required : false)
 222     if xxd.found()
 223         lcms_dep = dependency('lcms2', version : req_version, required : get_option('cms'))
 224         if lcms_dep.found()
 225             conf_data.set('HAVE_LCMS', 1)
 226             conf_data.set('HAVE_LCMS2', 1)
 227             summary({'cms' : ['color management supported:', true]}, section : 'Configuration', bool_yn : true)
 228         else
 229             summary({'cms' : ['lcms2' + req_version + ' not found - color management supported:', false]}, section : 'Configuration', bool_yn : true)
 230         endif
 231     else
 232         summary({'cms' : ['xxd or xxdi.pl not found - color management supported:', false]}, section : 'Configuration', bool_yn : true)
 233     endif
 234 else
 235     summary({'cms' : ['disabled - color management supported:', false]}, section : 'Configuration', bool_yn : true)
 236 endif
 237
 238 ddjvuapi_dep = []
 239 req_version = '>=2.5.27'
 240 option = get_option('djvu')
 241 if not option.disabled()
 242     ddjvuapi_dep = dependency('ddjvuapi', version : req_version, required : get_option('djvu'))
 243     if ddjvuapi_dep.found()
 244         conf_data.set('HAVE_DJVU', 1)
 245         summary({'djvu' : ['djvu files supported:', true]}, section : 'Configuration', bool_yn : true)
 246     else
 247         summary({'djvu' : ['ddjvuapi ' + req_version + ' not found - djvu files supported:', false]}, section : 'Configuration', bool_yn : true)
 248     endif
 249 else
 250     summary({'djvu' : ['disabled - djvu files supported:', false]}, section : 'Configuration', bool_yn : true)
 251 endif
 252
 253 option = get_option('evince')
 254 if not option.disabled()
 255     evince = find_program('evince', required : false)
 256     if evince.found()
 257         summary({'print preview' : ['print preview supported:', true]}, section : 'Configuration', bool_yn : true)
 258     else
 259         summary({'print preview' : ['evince not found - print preview supported:', false]}, section : 'Configuration', bool_yn : true)
 260     endif
 261 else
 262     summary({'print preview' : ['disabled - print preview supported:', false]}, section : 'Configuration', bool_yn : true)
 263 endif
 264
 265 # Required only for seg. fault stacktrace and backtrace debugging
 266 option = get_option('execinfo')
 267 if not option.disabled()
 268     result = cc.check_header('execinfo.h')
 269     if result
 270         conf_data.set('HAVE_EXECINFO_H', 1)
 271         summary({'execinfo' : ['stacktrace supported:', true]}, section : 'Configuration', bool_yn : true)
 272     else
 273         summary({'execinfo' : ['stacktrace supported:', false]}, section : 'Configuration', bool_yn : true)
 274     endif
 275 else
 276     summary({'execinfo' : ['stacktrace supported:', false]}, section : 'Configuration', bool_yn : true)
 277 endif
 278
 279 exiv2_dep = []
 280 # See https://github.com/BestImageViewer/geeqie/issues/1090
 281 # for the reason for 0.28.0 exclusion
 282 req_version = ['>=0.11', '!=0.28.0']
 283
 284 req_version_str = ''
 285 foreach req_version_str_ : req_version
 286     req_version_str += req_version_str_
 287 endforeach
 288
 289 option = get_option('exiv2')
 290 if not option.disabled()
 291     exiv2_dep = dependency('exiv2', version : req_version, required : get_option('exiv2'))
 292     if exiv2_dep.found()
 293         conf_data.set('HAVE_EXIV2', 1)
 294         summary({'exiv2' : ['image metadata processed by exiv2:', true]}, section : 'Configuration', bool_yn : true)
 295     else
 296         summary({'exiv2' : ['exiv2 ' + req_version_str + ' not found - image data not processed by exiv2:', false]}, section : 'Configuration', bool_yn : true)
 297     endif
 298 else
 299     summary({'exiv2' : ['disabled - image data processed by exiv2:', false]}, section : 'Configuration', bool_yn : true)
 300 endif
 301
 302 champlain_dep = []
 303 champlain_gtk_dep = []
 304 clutter_dep = []
 305 clutter_gtk_dep = []
 306 req_version_champlain = '>=0.12'
 307 req_version_champlain_gtk = '>=0.12'
 308 req_version_clutter = '>=1.0'
 309 req_version_clutter_gtk = '>=1.0'
 310 option = get_option('gps-map')
 311 if not option.disabled()
 312     champlain_dep = dependency('champlain-0.12', version : req_version_champlain, required : get_option('gps-map'))
 313     champlain_gtk_dep = dependency('champlain-gtk-0.12', version : req_version_champlain_gtk, required : get_option('gps-map'))
 314     if champlain_dep.found() and champlain_gtk_dep.found()
 315         clutter_dep = dependency('clutter-1.0', version : req_version_clutter, required : get_option('gps-map'))
 316         clutter_gtk_dep = dependency('clutter-gtk-1.0', version : req_version_clutter_gtk, required : get_option('gps-map'))
 317         if clutter_dep.found() and clutter_gtk_dep.found()
 318             conf_data.set('HAVE_CLUTTER', 1)
 319             conf_data.set('HAVE_LIBCHAMPLAIN', 1)
 320             conf_data.set('HAVE_LIBCHAMPLAIN_GTK', 1)
 321             summary({'gps-map' : ['GPS map displayed', true]}, section : 'Configuration', bool_yn : true)
 322         else
 323             if not clutter_dep.found()
 324                 summary({'gps-map-clutter' : ['clutter-1.0 ' + req_version_clutter + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 325             endif
 326             if not clutter_gtk_dep.found()
 327                 summary({'gps-map-clutter-gtk' : ['clutter-gtk-1.0 ' + req_version_clutter_gtk + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 328             endif
 329         endif
 330     else
 331         if not champlain_dep.found()
 332             summary({'gps-map-champlain' : ['champlain-0.12 ' + req_version_champlain + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 333         endif
 334         if not champlain_gtk_dep.found()
 335             summary({'gps-map-champlain-gtk' : ['champlain-gtk-0.12 ' + req_version_champlain_gtk + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 336         endif
 337     endif
 338 else
 339     summary({'gps-map' : ['disabled - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 340 endif
 341
 342 libheif_dep = []
 343 req_version = '>=1.3.2'
 344 option = get_option('heif')
 345 if not option.disabled()
 346     libheif_dep = dependency('libheif', version : req_version, required : get_option('heif'))
 347     if libheif_dep.found()
 348         conf_data.set('HAVE_HEIF', 1)
 349         summary({'heif' : ['heif files supported:', true]}, section : 'Configuration', bool_yn : true)
 350     else
 351         summary({'heif' : ['libheif ' + req_version + ' not found - heif files supported:', false]}, section : 'Configuration', bool_yn : true)
 352     endif
 353 else
 354     summary({'heif' : ['disabled - heif files supported:', false]}, section : 'Configuration', bool_yn : true)
 355 endif
 356
 357 libopenjp2_dep = []
 358 req_version = '>=2.3.0'
 359 option = get_option('j2k')
 360 if not option.disabled()
 361     libopenjp2_dep = dependency('libopenjp2', version : req_version, required : get_option('j2k'))
 362     if libopenjp2_dep.found()
 363         conf_data.set('HAVE_J2K', 1)
 364         summary({'j2k' : ['j2k files supported:', true]}, section : 'Configuration', bool_yn : true)
 365     else
 366         summary({'j2k' : ['libopenjp2 ' + req_version + ' not found - j2k files supported:', false]}, section : 'Configuration', bool_yn : true)
 367     endif
 368 else
 369     summary({'j2k' : ['disabled - j2k files supported:', false]}, section : 'Configuration', bool_yn : true)
 370 endif
 371
 372 libjpeg_dep = []
 373 option = get_option('jpeg')
 374 if not option.disabled()
 375 libjpeg_dep = dependency('libjpeg', required : get_option('jpeg'))
 376     if libjpeg_dep.found()
 377         if cc.has_function('jpeg_destroy_decompress', dependencies : libjpeg_dep)
 378             conf_data.set('HAVE_JPEG', 1)
 379             summary({'jpeg' : ['jpeg files supported:', true]}, section : 'Configuration', bool_yn : true)
 380         else
 381             summary({'jpeg' : ['jpeg_destroy_decompress not found - jpeg files supported:', false]}, section : 'Configuration', bool_yn : true)
 382         endif
 383     else
 384         summary({'jpeg' : ['libjpeg: not found', false]}, section : 'Configuration', bool_yn : true)
 385     endif
 386 else
 387     summary({'jpeg' : ['disabled - jpeg files supported:', false]}, section : 'Configuration', bool_yn : true)
 388 endif
 389
 390 libjxl_dep = []
 391 req_version = '>=0.3.7'
 392 option = get_option('jpegxl')
 393 if not option.disabled()
 394     libjxl_dep = dependency('libjxl', version : req_version, required : get_option('jpegxl'))
 395     if libjxl_dep.found()
 396         conf_data.set('HAVE_JPEGXL', 1)
 397         summary({'jpegxl' : ['jpegxl files supported:', true]}, section : 'Configuration', bool_yn : true)
 398     else
 399         summary({'jpegxl' : ['libjxl ' + req_version + ' not found - jpegxl files supported:', false]}, section : 'Configuration', bool_yn : true)
 400     endif
 401 else
 402     summary({'jpegxl' : ['disabled - jpegxl files supported:', false]}, section : 'Configuration', bool_yn : true)
 403 endif
 404
 405 libraw_dep = []
 406 req_version = '>=0.20'
 407 option = get_option('libraw')
 408 if not option.disabled()
 409     libraw_dep = dependency('libraw', version : req_version, required : get_option('libraw'))
 410     if libraw_dep.found()
 411         conf_data.set('HAVE_RAW', 1)
 412         summary({'libraw' : ['.cr3 files supported:', true]}, section : 'Configuration', bool_yn : true)
 413     else
 414         summary({'libraw' : ['libraw ' + req_version + ' not found - .cr3 files supported:', false]}, section : 'Configuration', bool_yn : true)
 415     endif
 416 else
 417     summary({'libraw' : ['disabled - .cr3 files supported:', false]}, section : 'Configuration', bool_yn : true)
 418 endif
 419
 420 lua_dep = []
 421 req_version = '>=5.3'
 422 option = get_option('lua')
 423 if not option.disabled()
 424     foreach name : ['lua', 'lua5.3', 'lua-5.3', 'lua53']
 425         lua_dep = dependency(name, version: req_version, required: get_option('lua'))
 426         if lua_dep.found()
 427             break
 428         endif
 429     endforeach
 430     if lua_dep.found()
 431         conf_data.set('HAVE_LUA', 1)
 432         summary({'lua' : ['lua supported:', true]}, section : 'Configuration', bool_yn : true)
 433     else
 434         summary({'lua' : ['lua ' + req_version + ' not found - lua supported:', false]}, section : 'Configuration', bool_yn : true)
 435     endif
 436 else
 437     summary({'lua' : ['disabled - lua supported:', false]}, section : 'Configuration', bool_yn : true)
 438 endif
 439
 440 option = get_option('pandoc')
 441 if not option.disabled()
 442     pandoc = find_program('pandoc', required : false)
 443     if pandoc.found()
 444         readme_html = custom_target(
 445             'README.html',
 446             input: 'README.md',
 447             output: 'README.html',
 448             command: [pandoc, '@INPUT@', '-o', '@OUTPUT@'],
 449             install: true,
 450             install_dir: helpdir)
 451
 452         summary({'README' : ['README.html created:', true]}, section : 'Documentation', bool_yn : true)
 453     else
 454         summary({'README' : ['pandoc not found - README.html created:', false]}, section : 'Documentation', bool_yn : true)
 455     endif
 456     install_data('README.md', 'COPYING', 'TODO', install_dir : helpdir)
 457 else
 458     summary({'pandoc' : ['disabled - README.html created:', false]}, section : 'Documentation', bool_yn : true)
 459 endif
 460
 461 poppler_glib_dep = []
 462 req_version = '>=0.62'
 463 option = get_option('pdf')
 464 if not option.disabled()
 465     poppler_glib_dep = dependency('poppler-glib', version : req_version, required : get_option('pdf'))
 466     if poppler_glib_dep.found()
 467         conf_data.set('HAVE_PDF', 1)
 468         summary({'pdf'  : ['pdf files supported:', true]}, section : 'Configuration', bool_yn : true)
 469     else
 470         summary({'pdf' : ['poppler-glib ' + req_version + ' not found - pdf files supported:', false]}, section : 'Configuration', bool_yn : true)
 471     endif
 472 else
 473     summary({'pdf' : ['disabled - pdf files supported:', false]}, section : 'Configuration', bool_yn : true)
 474 endif
 475
 476 gspell_dep = []
 477 req_version = '>=1.6'
 478 option = get_option('spell')
 479 if not option.disabled()
 480     gspell_dep = dependency('gspell-1', version : req_version, required: get_option('spell'))
 481     if gspell_dep.found()
 482         conf_data.set('HAVE_SPELL', 1)
 483         summary({'spell' : ['spelling checks enabled', true]}, section : 'Configuration', bool_yn : true)
 484     else
 485         summary({'spell' : ['gspell-1 ' + req_version + ' not found - spelling checks enabled', false]}, section : 'Configuration', bool_yn : true)
 486     endif
 487 else
 488     summary({'spell' : ['disabled - spelling checks enabled', false]}, section : 'Configuration', bool_yn : true)
 489 endif
 490
 491 tiff_dep = []
 492 option = get_option('tiff')
 493 if not option.disabled()
 494     tiff_dep = dependency('libtiff-4', required: get_option('tiff'))
 495     if tiff_dep.found()
 496         if cc.has_function('TIFFClientOpen', dependencies : tiff_dep)
 497             conf_data.set('HAVE_TIFF', 1)
 498             summary({'tiff' : ['tiff files supported:', true]}, section : 'Configuration', bool_yn : true)
 499         else
 500             summary({'tiff' : ['TIFFClientOpen not found - tiff files supported:', false]}, section : 'Configuration', bool_yn : true)
 501         endif
 502     else
 503         summary({'tiff' : ['libtiff not found - tiff files supported:', false]}, section : 'Configuration', bool_yn : true)
 504     endif
 505 else
 506     summary({'tiff' : ['disabled - tiff files supported:', false]}, section : 'Configuration', bool_yn : true)
 507 endif
 508
 509 libffmpegthumbnailer_dep = []
 510 req_version = '>=2.1.0'
 511 option = get_option('videothumbnailer')
 512 if not option.disabled()
 513     libffmpegthumbnailer_dep = dependency('libffmpegthumbnailer',
 514         version : req_version,
 515         required : get_option('videothumbnailer'))
 516
 517     if libffmpegthumbnailer_dep.found()
 518         conf_data.set('HAVE_FFMPEGTHUMBNAILER', 1)
 519         summary({'videothumbnailer' : ['thumbnails of video files supported:', true]}, section : 'Configuration', bool_yn : true)
 520
 521         result = cc.has_member('struct video_thumbnailer_struct', 'prefer_embedded_metadata', prefix : '#include <libffmpegthumbnailer/videothumbnailerc.h>')
 522         if result
 523             conf_data.set('HAVE_FFMPEGTHUMBNAILER_METADATA', 1)
 524         endif
 525         summary({'fmpegthumbnailer_metadata' : ['fmpegthumbnailer_metadata found:', result]}, section : 'Thumbnailer', bool_yn : true)
 526
 527         result = cc.has_member('struct image_data_struct', 'image_data_width', prefix : '#include <libffmpegthumbnailer/videothumbnailerc.h>' )
 528         if result
 529             conf_data.set('HAVE_FFMPEGTHUMBNAILER_RGB', 1)
 530         endif
 531         summary({'fmpegthumbnailer_rgb' : ['fmpegthumbnailer_rgb found:', result]}, section : 'Thumbnailer', bool_yn : true)
 532
 533         result = cc.has_function('video_thumbnailer_set_size', dependencies : libffmpegthumbnailer_dep)
 534         if result
 535             conf_data.set('HAVE_FFMPEGTHUMBNAILER_WH', 1)
 536         endif
 537         summary({'fmpegthumbnailer_set_size' : ['fmpegthumbnailer_set_size found:', result]}, section : 'Thumbnailer', bool_yn : true)
 538     else
 539         summary({'videothumbnailer' : ['libvideothumbnailer ' + req_version + ' not found - thumbnails of video files supported', false]}, section : 'Configuration', bool_yn : true)
 540     endif
 541 else
 542     summary({'videothumbnailer' : ['disabled -thumbnails of video files supported', false]}, section : 'Configuration', bool_yn : true)
 543 endif
 544
 545 # libpixbufloader-webp is not loaded as part of libgdk-pixbuf. Just issue
 546 # a warning if not installed
 547 libwebp_dir = dependency('gdk-pixbuf-2.0', method: 'pkg-config').get_variable(pkgconfig: 'gdk_pixbuf_moduledir', internal: 'gdk_pixbuf_moduledir')
 548
 549 if libwebp_dir.contains('loaders')
 550     libwebp_dep = cc.find_library('pixbufloader-webp', dirs : libwebp_dir, required : false)
 551     if libwebp_dep.found()
 552         summary({'webp' : ['webp files supported:', true]}, section : 'Configuration', bool_yn : true)
 553     else
 554         summary({'webp' : ['webp-pixbuf-loader not installed - webp files supported:', false]}, section : 'Configuration', bool_yn : true)
 555     endif
 556 else
 557     summary({'webp' : ['webp-pixbuf-loader not installed - webp files supported:', false]}, section : 'Configuration', bool_yn : true)
 558 endif
 559
 560 # Check for nl_langinfo and _NL_TIME_FIRST_WEEKDAY
 561 code = '''#include <langinfo.h>
 562 #include<stdio.h>
 563 int main (int argc, char ** argv) {
 564     char *c;
 565     c =  nl_langinfo(_NL_TIME_FIRST_WEEKDAY);
 566     return 0;
 567 }'''
 568 if cc.links(code, name : 'nl_langinfo and _NL_TIME_FIRST_WEEKDAY')
 569     conf_data.set('HAVE__NL_TIME_FIRST_WEEKDAY', 1)
 570     summary({'nl_langinfo' : ['first weekday depends on locale:', true]}, section : 'Documentation', bool_yn : true)
 571 else
 572     summary({'nl_langinfo' : ['nl_langinfo not found - first weekday depends on locale:', false, 'first weekday defaults to Monday']}, section : 'Documentation', bool_yn : true)
 573 endif
 574
 575 conf_data.set_quoted('GETTEXT_PACKAGE', meson.project_name())
 576 conf_data.set_quoted('GQ_APPDIR', gq_appdir)
 577 conf_data.set_quoted('GQ_BINDIR', gq_bindir)
 578 conf_data.set_quoted('GQ_HELPDIR', gq_helpdir)
 579 conf_data.set_quoted('GQ_HTMLDIR', gq_htmldir)
 580 conf_data.set_quoted('GQ_LOCALEDIR', gq_localedir)
 581
 582 conf_data.set_quoted('PACKAGE', meson.project_name())
 583 conf_data.set_quoted('PACKAGE_NAME', meson.project_name())
 584 conf_data.set_quoted('PACKAGE_STRING', meson.project_version())
 585 conf_data.set_quoted('PACKAGE_TARNAME', meson.project_name())
 586 conf_data.set_quoted('PACKAGE_VERSION', meson.project_version())
 587 conf_data.set_quoted('VERSION', meson.project_version())
 588
 589 configure_file(input : 'config.h.in',
 590                output : 'config.h',
 591                encoding : 'UTF-8',
 592                configuration : conf_data)
 593
 594 # For shellcheck on scripts
 595 script_sources = []
 596 subdir('scripts')
 597
 598 # Process subdirs before the sources
 599 subdir('po')
 600 subdir('plugins')
 601
 602 # Generate the executable
 603 subdir('src')
 604
 605 # Generate the help files
 606 subdir('doc')
 607
 608 # Install other project files
 609 if running_from_git
 610     cmd = [find_program('gen_changelog.sh'), meson.current_source_dir(), meson.current_build_dir()]
 611     custom_target(
 612         'ChangeLog',
 613         input: 'ChangeLog.gqview',
 614         output: ['ChangeLog', 'ChangeLog.html'],
 615         command: cmd,
 616         install: true,
 617         install_dir: helpdir)
 618     meson.add_dist_script(cmd)
 619     summary({'ChangeLog' : ['ChangeLog, ChangeLog.html created:', true]}, section : 'Documentation', bool_yn : true)
 620 elif fs.exists('ChangeLog.html')
 621     install_data('ChangeLog', 'ChangeLog.html', install_dir: helpdir)
 622     summary({'ChangeLog' : ['ChangeLog, ChangeLog.html installed from dist:', true]}, section : 'Documentation', bool_yn : true)
 623 endif
 624
 625 install_data('geeqie.png', install_dir : icondir)
 626 install_data('geeqie.1', install_dir : mandir1)
 627
 628 i18n.merge_file(
 629     input : 'geeqie.desktop.in',
 630     output : 'geeqie.desktop',
 631     type : 'desktop',
 632     po_dir : podir,
 633     install : true,
 634     install_dir : join_paths(datadir, 'applications'))
 635
 636 i18n.merge_file(
 637     input : 'org.geeqie.Geeqie.appdata.xml.in',
 638     output : 'org.geeqie.Geeqie.appdata.xml',
 639     type : 'xml',
 640     po_dir : podir,
 641     install : true,
 642     install_dir : appdatadir)
 643
 644 configure_file(input: 'geeqie.spec.in', output: 'geeqie.spec', configuration: conf_data)
 645
 646 # Basic test of the executable
 647 xvfb = find_program('xvfb-run', required : false)
 648 if xvfb.found()
 649     test('Basic test', xvfb, args: ['--auto-servernum', geeqie_exe, '--version'], timeout: 100)
 650     summary({'xvfb' : ['Test runs:', true]}, section : 'Testing', bool_yn : true)
 651 else
 652     summary({'xvfb' : ['Test runs:', false]}, section : 'Testing', bool_yn : true)
 653 endif
 654
 655 # Shellcheck
 656 shellcheck_exe = find_program('shellcheck', required : false)
 657 script_sources += files('gen_changelog.sh',
 658 'geeqie-install-debian.sh',
 659 'version.sh')
 660
 661 if shellcheck_exe.found()
 662     foreach script : script_sources
 663         test('Shellcheck', shellcheck_exe, args: ['--norc', '--shell=sh', '--enable=add-default-case,avoid-nullary-conditions,check-unassigned-uppercase,deprecate-which,quote-safe-variables', script], timeout: 100)
 664     endforeach
 665     summary({'shellcheck' : ['Test runs:', true]}, section : 'Testing', bool_yn : true)
 666 else
 667     summary({'shellcheck' : ['Test runs:', false]}, section : 'Testing', bool_yn : true)
 668 endif