meson.build

   1 # This file is a part of Geeqie project (https://www.geeqie.org/).
   2 # Copyright (C) 2008 - 2022 The Geeqie Team
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13
  14 # Meson default directories used in this project:
  15 # prefix - /usr/local
  16 # bindir - bin
  17 # datadir - share
  18
  19 # Meson core options:
  20 # buildtype
  21 # debug
  22
  23 # Project expanded default directories:
  24 # prefix        /usr/local/
  25 # bindir        /usr/local/bin                          geeqie executable
  26 # gq_bindir     /usr/local/lib/geeqie               *   plugins scripts
  27 # datadir       /usr/local/share/
  28 #               /usr/local/share/applications           geeqie.desktop
  29 # [gq_]appdir   /usr/local/share/geeqie/            *   template.desktop
  30 # desktopdir    /usr/local/share/geeqie/applications    plugin desktop files
  31 # appdatadir    /usr/local/share/metainfo               org.geeqie.Geeqie.appdata.xml
  32 # icondir       /usr/local/share/pixmaps                geeqie.png icon
  33 # [gq_]helpdir  /usr/local/share/doc/geeqie         *   readme files etc.
  34 # [gq_]htmldir  /usr/local/share/doc/geeqie/html    *   help files
  35 # gq_localedir  /usr/locale/share/locale
  36 # mandir1       /usr/local/share/man/man1               man page
  37 # podir         project_root/po
  38
  39 # * See meson_options.txt file
  40
  41 project(
  42     'geeqie',
  43     'c',
  44     'cpp',
  45     version : run_command('./version.sh', check : true).stdout().strip(),
  46     license : ['GPL-2.0-or-later'],
  47     meson_version : '>=0.53.0',
  48     default_options : ['warning_level=3', 'buildtype=debugoptimized']
  49 )
  50
  51 # To inhibit warnings from the generated files icons_inline.h and ui_icons.h
  52 add_global_arguments('-Wno-overlength-strings', language : 'c')
  53
  54 # To compile originally-C files as C++
  55 add_global_arguments('-fpermissive', language : 'cpp')
  56 add_global_arguments('-Wno-error=deprecated-declarations', language : 'cpp')
  57 add_global_arguments('-Wno-error=sign-compare', language : 'cpp')
  58 add_global_arguments('-Wno-error=return-type', language : 'cpp')
  59 add_global_arguments('-Wno-error=literal-suffix', language : 'cpp')
  60 add_global_arguments('-Wno-error=write-strings', language : 'cpp')
  61
  62 # Project requirements
  63 project_sources = []
  64 gnome = import('gnome')
  65 thread_dep = dependency('threads')
  66 cc = meson.get_compiler('c')
  67 i18n = import('i18n')
  68 fs = import('fs')
  69 configuration_inc = include_directories('.')
  70
  71 # External programs
  72 gdk_pixbuf_csource = find_program('gdk-pixbuf-csource', required : true)
  73 glib_genmarshal = find_program('glib-genmarshal', required : true)
  74 gnome_doc_tool = find_program('yelp-build', required : false)
  75 if gnome_doc_tool.found()
  76     summary({'help' : ['Help files created:', true]}, section : 'Documentation', bool_yn : true)
  77 else
  78     summary({'help' : ['yelp-build not found - Help files created:', false]}, section : 'Documentation', bool_yn : true)
  79 endif
  80
  81 running_from_git = find_program('git', required: false).found() and fs.is_dir('.git')
  82
  83 debug = get_option('debug')
  84
  85 # Note that main.cc sets prefix to the directory above where the executable is run from.
  86 # This is to allow AppImages to be used
  87
  88 # These gq_* variables are paths relative to /prefix/,
  89 # and are also used in defines in the source as GQ_*
  90 if get_option('gq_appdir') == ''
  91     gq_appdir = join_paths(get_option('datadir'), 'geeqie')
  92 else
  93     gq_appdir = get_option('gq_appdir')
  94 endif
  95
  96 # This is not the same as Meson bindir
  97 if get_option('gq_bindir') == ''
  98     gq_bindir = 'lib/geeqie'
  99 else
 100     gq_bindir = get_option('gq_bindir')
 101 endif
 102
 103 if get_option('gq_helpdir') == ''
 104     gq_helpdir = join_paths(get_option('datadir'), 'doc/geeqie')
 105 else
 106     gq_helpdir = get_option('gq_helpdir')
 107 endif
 108
 109 if get_option('gq_htmldir') == ''
 110     gq_htmldir = join_paths(get_option('datadir'), 'doc/geeqie/html')
 111 else
 112     gq_htmldir = get_option('gq_htmldir')
 113 endif
 114
 115 if get_option('gq_localedir') == ''
 116     gq_localedir = join_paths(get_option('datadir'), 'locale')
 117 else
 118     gq_localedir = get_option('gq_localedir')
 119 endif
 120
 121
 122 # Set up the absolute directory paths used
 123 prefix = get_option('prefix')
 124 datadir = join_paths(prefix, get_option('datadir'))
 125
 126 # Installation paths are absolute
 127 appdir = join_paths(prefix, gq_appdir)
 128 appdatadir = join_paths(datadir, 'metainfo')
 129 desktopdir = join_paths(datadir, meson.project_name(), 'applications')
 130 helpdir = join_paths(prefix, gq_helpdir)
 131 htmldir = join_paths(prefix, gq_htmldir)
 132 icondir = join_paths(datadir, 'pixmaps')
 133 mandir1 = join_paths(datadir, 'man', 'man1')
 134
 135 podir = join_paths(meson.source_root(), 'po')
 136
 137 summary({'gq_appdir': gq_appdir,
 138         'gq_bindir': gq_helpdir,
 139         'gq_helpdir': gq_helpdir,
 140         'gq_htmldir': gq_htmldir,
 141         'gq_localedir': gq_localedir,
 142         }, section: 'Directories')
 143
 144 # Create the define constants used in the sources. Set via config.h.in
 145 conf_data = configuration_data()
 146 conf_data.set_quoted('VERSION', meson.project_version())
 147 conf_data.set('DEBUG', debug)
 148
 149 gtk_dep = dependency('gtk+-3.0', version : '>=3.22', required: true)
 150 glib_dep = dependency('glib-2.0', version : '>=2.52', required: true)
 151
 152 libarchive_dep = []
 153 req_version = '>=3.4.0'
 154 option = get_option('archive')
 155 if not option.disabled()
 156     libarchive_dep = dependency('libarchive', version : req_version, required : get_option('archive'))
 157     if libarchive_dep.found()
 158         conf_data.set('HAVE_ARCHIVE', 1)
 159         summary({'archive' : ['archive files e.g. .zip supported:', true]}, section : 'Configuration', bool_yn : true)
 160     else
 161         summary({'archive' : ['libarchive ' + req_version + ' not found - archive files e.g. .zip supported::', false]}, section : 'Configuration', bool_yn : true)
 162     endif
 163 else
 164     summary({'archive' : ['disabled - archive files e.g. .zip supported:', false]}, section : 'Configuration', bool_yn : true)
 165 endif
 166
 167 lcms_dep = []
 168 req_version = '>=2.0'
 169 option = get_option('cms')
 170 if not option.disabled()
 171     lcms_dep = dependency('lcms2', version : req_version, required : get_option('cms'))
 172     if lcms_dep.found()
 173         conf_data.set('HAVE_LCMS', 1)
 174         conf_data.set('HAVE_LCMS2', 1)
 175         summary({'cms' : ['color management supported:', true]}, section : 'Configuration', bool_yn : true)
 176     else
 177         summary({'cms' : ['lcms2' + req_version + ' not found - color management supported:', false]}, section : 'Configuration', bool_yn : true)
 178     endif
 179 else
 180     summary({'cms' : ['disabled - color management supported:', false]}, section : 'Configuration', bool_yn : true)
 181 endif
 182
 183 ddjvuapi_dep = []
 184 req_version = '>=2.5.27'
 185 option = get_option('djvu')
 186 if not option.disabled()
 187     ddjvuapi_dep = dependency('ddjvuapi', version : req_version, required : get_option('djvu'))
 188     if ddjvuapi_dep.found()
 189         conf_data.set('HAVE_DJVU', 1)
 190         summary({'djvu' : ['djvu files supported:', true]}, section : 'Configuration', bool_yn : true)
 191     else
 192         summary({'djvu' : ['ddjvuapi ' + req_version + ' not found - djvu files supported:', false]}, section : 'Configuration', bool_yn : true)
 193     endif
 194 else
 195     summary({'djvu' : ['disabled - djvu files supported:', false]}, section : 'Configuration', bool_yn : true)
 196 endif
 197
 198 exiv2_dep = []
 199 req_version = '>=0.11'
 200 option = get_option('exiv2')
 201 if not option.disabled()
 202     exiv2_dep = dependency('exiv2', version : req_version, required : get_option('exiv2'))
 203     if exiv2_dep.found()
 204         conf_data.set('HAVE_EXIV2', 1)
 205         summary({'exiv2' : ['image metadata processed by exiv2:', true]}, section : 'Configuration', bool_yn : true)
 206     else
 207         summary({'exiv2' : ['exiv2 ' + req_version + ' not found - image data not processed by exiv2:', false]}, section : 'Configuration', bool_yn : true)
 208     endif
 209 else
 210     summary({'exiv2' : ['disabled - image data processed by exiv2:', false]}, section : 'Configuration', bool_yn : true)
 211 endif
 212
 213 libffmpegthumbnailer_dep = []
 214 req_version = '>=2.1.0'
 215 option = get_option('videothumbnailer')
 216 if not option.disabled()
 217     libffmpegthumbnailer_dep = dependency('libffmpegthumbnailer',
 218         version : req_version,
 219         required : get_option('videothumbnailer'))
 220
 221     if libffmpegthumbnailer_dep.found()
 222         conf_data.set('HAVE_FFMPEGTHUMBNAILER', 1)
 223         summary({'videothumbnailer' : ['thumbnails of video files supported:', true]}, section : 'Configuration', bool_yn : true)
 224
 225         result = cc.has_member('struct video_thumbnailer_struct', 'prefer_embedded_metadata', prefix : '#include <libffmpegthumbnailer/videothumbnailerc.h>')
 226         if result
 227             conf_data.set('HAVE_FFMPEGTHUMBNAILER_METADATA', 1)
 228         endif
 229         summary({'fmpegthumbnailer_metadata' : ['fmpegthumbnailer_metadata found:', result]}, section : 'Thumbnailer', bool_yn : true)
 230
 231         result = cc.has_member('struct image_data_struct', 'image_data_width', prefix : '#include <libffmpegthumbnailer/videothumbnailerc.h>' )
 232         if result
 233             conf_data.set('HAVE_FFMPEGTHUMBNAILER_RGB', 1)
 234         endif
 235         summary({'fmpegthumbnailer_rgb' : ['fmpegthumbnailer_rgb found:', result]}, section : 'Thumbnailer', bool_yn : true)
 236
 237         result = cc.has_function('video_thumbnailer_set_size', dependencies : libffmpegthumbnailer_dep)
 238         if result
 239             conf_data.set('HAVE_FFMPEGTHUMBNAILER_WH', 1)
 240         endif
 241         summary({'fmpegthumbnailer_set_size' : ['fmpegthumbnailer_set_size found:', result]}, section : 'Thumbnailer', bool_yn : true)
 242     else
 243         summary({'videothumbnailer' : ['libvideothumbnailer ' + req_version + ' not found - thumbnails of video files supported', false]}, section : 'Configuration', bool_yn : true)
 244     endif
 245 else
 246     summary({'videothumbnailer' : ['disabled -thumbnails of video files supported', false]}, section : 'Configuration', bool_yn : true)
 247 endif
 248
 249 champlain_dep = []
 250 champlain_gtk_dep = []
 251 clutter_dep = []
 252 clutter_gtk_dep = []
 253 req_version_champlain = '>=0.12'
 254 req_version_champlain_gtk = '>=0.12'
 255 req_version_clutter = '>=1.0'
 256 req_version_clutter_gtk = '>=1.0'
 257 option = get_option('gps-map')
 258 if not option.disabled()
 259     champlain_dep = dependency('champlain-0.12', version : req_version_champlain, required : get_option('gps-map'))
 260     champlain_gtk_dep = dependency('champlain-gtk-0.12', version : req_version_champlain_gtk, required : get_option('gps-map'))
 261     if champlain_dep.found() and champlain_gtk_dep.found()
 262         clutter_dep = dependency('clutter-1.0', version : req_version_clutter, required : get_option('gps-map'))
 263         clutter_gtk_dep = dependency('clutter-gtk-1.0', version : req_version_clutter_gtk, required : get_option('gps-map'))
 264         if clutter_dep.found() and clutter_gtk_dep.found()
 265             conf_data.set('HAVE_CLUTTER', 1)
 266             conf_data.set('HAVE_LIBCHAMPLAIN', 1)
 267             conf_data.set('HAVE_LIBCHAMPLAIN_GTK', 1)
 268             summary({'gps-map' : ['GPS map displayed', true]}, section : 'Configuration', bool_yn : true)
 269         else
 270             if not clutter_dep.found()
 271                 summary({'gps-map-clutter' : ['clutter-1.0 ' + req_version_clutter + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 272             endif
 273             if not clutter_gtk_dep.found()
 274                 summary({'gps-map-clutter-gtk' : ['clutter-gtk-1.0 ' + req_version_clutter_gtk + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 275             endif
 276         endif
 277     else
 278         if not champlain_dep.found()
 279             summary({'gps-map-champlain' : ['champlain-0.12 ' + req_version_champlain + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 280         endif
 281         if not champlain_gtk_dep.found()
 282             summary({'gps-map-champlain-gtk' : ['champlain-gtk-0.12 ' + req_version_champlain_gtk + ' not found - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 283         endif
 284     endif
 285 else
 286     summary({'gps-map' : ['disabled - GPS map displayed:', false]}, section : 'Configuration', bool_yn : true)
 287 endif
 288
 289 libheif_dep = []
 290 req_version = '>=1.3.2'
 291 option = get_option('heif')
 292 if not option.disabled()
 293     libheif_dep = dependency('libheif', version : req_version, required : get_option('heif'))
 294     if libheif_dep.found()
 295         conf_data.set('HAVE_HEIF', 1)
 296         summary({'heif' : ['heif files supported:', true]}, section : 'Configuration', bool_yn : true)
 297     else
 298         summary({'heif' : ['libheif ' + req_version + ' not found - heif files supported:', false]}, section : 'Configuration', bool_yn : true)
 299     endif
 300 else
 301     summary({'heif' : ['disabled - heif files supported:', false]}, section : 'Configuration', bool_yn : true)
 302 endif
 303
 304 libopenjp2_dep = []
 305 req_version = '>=2.3.0'
 306 option = get_option('j2k')
 307 if not option.disabled()
 308     libopenjp2_dep = dependency('libopenjp2', version : req_version, required : get_option('j2k'))
 309     if libopenjp2_dep.found()
 310         conf_data.set('HAVE_J2K', 1)
 311         summary({'j2k' : ['j2k files supported:', true]}, section : 'Configuration', bool_yn : true)
 312     else
 313         summary({'j2k' : ['libopenjp2 ' + req_version + ' not found - j2k files supported:', false]}, section : 'Configuration', bool_yn : true)
 314     endif
 315 else
 316     summary({'j2k' : ['disabled - j2k files supported:', false]}, section : 'Configuration', bool_yn : true)
 317 endif
 318
 319 libjpeg_dep = []
 320 option = get_option('jpeg')
 321 if not option.disabled()
 322 libjpeg_dep = dependency('libjpeg', required : get_option('jpeg'))
 323     if libjpeg_dep.found()
 324         if cc.has_function('jpeg_destroy_decompress', dependencies : libjpeg_dep)
 325             conf_data.set('HAVE_JPEG', 1)
 326             summary({'jpeg' : ['jpeg files supported:', true]}, section : 'Configuration', bool_yn : true)
 327         else
 328             summary({'jpeg' : ['jpeg_destroy_decompress not found - jpeg files supported:', false]}, section : 'Configuration', bool_yn : true)
 329         endif
 330     else
 331         summary({'jpeg' : ['libjpeg: not found', false]}, section : 'Configuration', bool_yn : true)
 332     endif
 333 else
 334     summary({'jpeg' : ['disabled - jpeg files supported:', false]}, section : 'Configuration', bool_yn : true)
 335 endif
 336
 337 libjxl_dep = []
 338 req_version = '>=0.3.7'
 339 option = get_option('jpegxl')
 340 if not option.disabled()
 341     libjxl_dep = dependency('libjxl', version : req_version, required : get_option('jpegxl'))
 342     if libjxl_dep.found()
 343         conf_data.set('HAVE_JPEGXL', 1)
 344         summary({'jpegxl' : ['jpegxl files supported:', true]}, section : 'Configuration', bool_yn : true)
 345     else
 346         summary({'jpegxl' : ['libjxl ' + req_version + ' not found - jpegxl files supported:', false]}, section : 'Configuration', bool_yn : true)
 347     endif
 348 else
 349     summary({'jpegxl' : ['disabled - jpegxl files supported:', false]}, section : 'Configuration', bool_yn : true)
 350 endif
 351
 352 libraw_dep = []
 353 req_version = '>=0.20'
 354 option = get_option('libraw')
 355 if not option.disabled()
 356     libraw_dep = dependency('libraw', version : req_version, required : get_option('libraw'))
 357     if libraw_dep.found()
 358         conf_data.set('HAVE_RAW', 1)
 359         summary({'libraw' : ['.cr3 files supported:', true]}, section : 'Configuration', bool_yn : true)
 360     else
 361         summary({'libraw' : ['libraw ' + req_version + ' not found - .cr3 files supported:', false]}, section : 'Configuration', bool_yn : true)
 362     endif
 363 else
 364     summary({'libraw' : ['disabled - .cr3 files supported:', false]}, section : 'Configuration', bool_yn : true)
 365 endif
 366
 367 lua_dep = []
 368 req_version = '>=5.3'
 369 option = get_option('lua')
 370 if not option.disabled()
 371     lua_dep = dependency('lua5.3',  version : req_version, required : get_option('lua'))
 372     if lua_dep.found()
 373         conf_data.set('HAVE_LUA', 1)
 374         summary({'lua' : ['lua supported:', true]}, section : 'Configuration', bool_yn : true)
 375     else
 376         summary({'lua' : ['lua5.3 ' + req_version + ' not found - lua supported:', false]}, section : 'Configuration', bool_yn : true)
 377     endif
 378 else
 379     summary({'lua' : ['disabled - lua supported:', false]}, section : 'Configuration', bool_yn : true)
 380 endif
 381
 382 poppler_glib_dep = []
 383 req_version = '>=0.62'
 384 option = get_option('pdf')
 385 if not option.disabled()
 386     poppler_glib_dep = dependency('poppler-glib', version : req_version, required : get_option('pdf'))
 387     if poppler_glib_dep.found()
 388         conf_data.set('HAVE_PDF', 1)
 389         summary({'pdf'  : ['pdf files supported:', true]}, section : 'Configuration', bool_yn : true)
 390     else
 391         summary({'pdf' : ['poppler-glib ' + req_version + ' not found - pdf files supported:', false]}, section : 'Configuration', bool_yn : true)
 392     endif
 393 else
 394     summary({'pdf' : ['disabled - pdf files supported:', false]}, section : 'Configuration', bool_yn : true)
 395 endif
 396
 397 gspell_dep = []
 398 req_version = '>=1.6'
 399 option = get_option('spell')
 400 if not option.disabled()
 401     gspell_dep = dependency('gspell-1', version : req_version, required: get_option('spell'))
 402     if gspell_dep.found()
 403         conf_data.set('HAVE_SPELL', 1)
 404         summary({'spell' : ['spelling checks enabled', true]}, section : 'Configuration', bool_yn : true)
 405     else
 406         summary({'spell' : ['gspell-1 ' + req_version + ' not found - spelling checks not enabled', false]}, section : 'Configuration', bool_yn : true)
 407     endif
 408 else
 409     summary({'spell' : ['disabled - spelling checks not enabled', false]}, section : 'Configuration', bool_yn : true)
 410 endif
 411
 412 tiff_dep = []
 413 option = get_option('tiff')
 414 if not option.disabled()
 415     tiff_dep = dependency('libtiff-4', required: get_option('tiff'))
 416     if tiff_dep.found()
 417         if cc.has_function('TIFFClientOpen', dependencies : tiff_dep)
 418             conf_data.set('HAVE_TIFF', 1)
 419             summary({'tiff' : ['tiff files supported:', true]}, section : 'Configuration', bool_yn : true)
 420         else
 421             summary({'tiff' : ['TIFFClientOpen not found - tiff files supported:', false]}, section : 'Configuration', bool_yn : true)
 422         endif
 423     else
 424         summary({'tiff' : ['libtiff not found - tiff files supported:', false]}, section : 'Configuration', bool_yn : true)
 425     endif
 426 else
 427     summary({'tiff' : ['disabled - tiff files supported:', false]}, section : 'Configuration', bool_yn : true)
 428 endif
 429
 430 libwebp_dep = []
 431 req_version = '>=0.6.1'
 432 option = get_option('webp')
 433 if not option.disabled()
 434     libwebp_dep = dependency('libwebp', version : req_version, required : get_option('webp'))
 435     if libwebp_dep.found()
 436         conf_data.set('HAVE_WEBP', 1)
 437         summary({'webp' : ['webp files supported:', true]}, section : 'Configuration', bool_yn : true)
 438     else
 439         summary({'webp' : ['libwebp ' + req_version + ' not found - webp files supported:', false]}, section : 'Configuration', bool_yn : true)
 440     endif
 441 else
 442     summary({'webp' : ['disabled - webp files supported:', false]}, section : 'Configuration', bool_yn : true)
 443 endif
 444
 445 # Check for nl_langinfo and _NL_TIME_FIRST_WEEKDAY
 446 code = '''#include <langinfo.h>
 447 #include<stdio.h>
 448 int main (int argc, char ** argv) {
 449     char *c;
 450     c =  nl_langinfo(_NL_TIME_FIRST_WEEKDAY);
 451     return 0;
 452 }'''
 453 if cc.links(code, name : 'nl_langinfo and _NL_TIME_FIRST_WEEKDAY')
 454     conf_data.set('HAVE__NL_TIME_FIRST_WEEKDAY', 1)
 455     summary({'nl_langinfo' : ['first weekday depends on locale:', true]}, section : 'Documentation', bool_yn : true)
 456 else
 457     summary({'nl_langinfo' : ['nl_langinfo not found - first weekday depends on locale:', false, 'first weekday defaults to Monday']}, section : 'Documentation', bool_yn : true)
 458 endif
 459
 460 result = cc.has_function('strverscmp', prefix : '#include <string.h>')
 461 if result
 462     conf_data.set('HAVE_STRVERSCMP', 1)
 463 endif
 464
 465 conf_data.set_quoted('GETTEXT_PACKAGE', meson.project_name())
 466 conf_data.set_quoted('GQ_APPDIR', gq_appdir)
 467 conf_data.set_quoted('GQ_BINDIR', gq_bindir)
 468 conf_data.set_quoted('GQ_HELPDIR', gq_helpdir)
 469 conf_data.set_quoted('GQ_HTMLDIR', gq_htmldir)
 470 conf_data.set_quoted('GQ_LOCALEDIR', gq_localedir)
 471
 472 conf_data.set_quoted('PACKAGE', meson.project_name())
 473 conf_data.set_quoted('PACKAGE_NAME', meson.project_name())
 474 conf_data.set_quoted('PACKAGE_STRING', meson.project_version())
 475 conf_data.set_quoted('PACKAGE_TARNAME', meson.project_name())
 476 conf_data.set_quoted('PACKAGE_VERSION', meson.project_version())
 477 conf_data.set_quoted('VERSION', meson.project_version())
 478
 479 configure_file(input : 'config.h.in',
 480                output : 'config.h',
 481                encoding : 'UTF-8',
 482                configuration : conf_data)
 483
 484 # Process subdirs before the sources
 485 subdir('po')
 486 subdir('plugins')
 487
 488 # Generate the executable
 489 subdir('src')
 490
 491 # Generate the help files
 492 subdir('doc')
 493
 494 # Install other project files
 495 if running_from_git
 496     custom_target(
 497         'ChangeLog',
 498         input: 'ChangeLog.gqview',
 499         output: ['ChangeLog', 'ChangeLog.html'],
 500         command: [find_program('gen_changelog.sh'), meson.current_source_dir(), meson.current_build_dir()],
 501         install: true,
 502         install_dir: helpdir)
 503     summary({'ChangeLog' : ['ChangeLog, ChangeLog.html created:', true]}, section : 'Documentation', bool_yn : true)
 504 else
 505     summary({'ChangeLog' : ['ChangeLog, ChangeLog.html created:', false]}, section : 'Documentation', bool_yn : true)
 506 endif
 507
 508 pandoc = find_program('pandoc', required : false)
 509 if pandoc.found()
 510     run_command(find_program('gen_readme.sh'), meson.source_root(), meson.build_root(), check : false)
 511
 512     install_data('README.md', 'COPYING', 'TODO', 'AUTHORS',
 513                  join_paths(meson.build_root(), 'README.html'),
 514                  install_dir : helpdir)
 515     summary({'README' : ['README.html created:', true]}, section : 'Documentation', bool_yn : true)
 516 else
 517     install_data('README.md', 'COPYING', 'TODO', 'AUTHORS',
 518                  install_dir : helpdir)
 519     summary({'README' : ['pandoc not found - README.html created:', false]}, section : 'Documentation', bool_yn : true)
 520 endif
 521
 522 evince = find_program('evince', required : false)
 523 if evince.found()
 524     summary({'print preview' : ['print preview supported:', true]}, section : 'Documentation', bool_yn : true)
 525 else
 526     summary({'print preview' : ['evince not found - print preview supported:', false]}, section : 'Documentation', bool_yn : true)
 527 endif
 528
 529 install_data('geeqie.png', install_dir : icondir)
 530 install_data('geeqie.1', install_dir : mandir1)
 531
 532 i18n.merge_file(
 533     input : 'geeqie.desktop.in',
 534     output : 'geeqie.desktop',
 535     type : 'desktop',
 536     po_dir : podir,
 537     install : true,
 538     install_dir : join_paths(datadir, 'applications'))
 539
 540 i18n.merge_file(
 541     input : 'org.geeqie.Geeqie.appdata.xml.in',
 542     output : 'org.geeqie.Geeqie.appdata.xml',
 543     type : 'xml',
 544     po_dir : podir,
 545     install : true,
 546     install_dir : appdatadir)
 547
 548 configure_file(input: 'geeqie.spec.in', output: 'geeqie.spec', configuration: conf_data)